reserve a,b,c,d,e,f for Real,
        k,m for Nat,
        D for non empty set,
        V for non trivial RealLinearSpace,
        u,v,w for Element of V,
        p,q,r for Element of ProjectiveSpace(V);
reserve o,p,q,r,s,t for Point of TOP-REAL 3,
        M for Matrix of 3,F_Real;

theorem Th49:
  for u,v,w,x being Element of TOP-REAL 3 st
  v is not zero & x is not zero & Dir v = Dir x holds
  |{u,v,w}| = 0 iff |{u,x,w}| = 0
  proof
    let u,v,w,x being Element of TOP-REAL 3;
    assume that
A1: v is not zero and
A2: x is not zero and
A3: Dir v = Dir x;
A4: are_Prop v,x by A1,A2,A3,ANPROJ_1:22;
    then consider a be Real such that
    a <> 0 and
A5: v = a * x by ANPROJ_1:1;
    consider b be Real such that
    b <> 0 and
A6: x = b * v by A4,ANPROJ_1:1;
    hereby
      assume
A7:   |{u,v,w}| = 0;
      thus |{u,x,w}| = b * |{u,v,w}| by A6,Th27
                    .= 0 by A7;
    end;
    assume
A8: |{u,x,w}| = 0;
    thus |{u,v,w}| = a * |{u,x,w}| by A5,Th27
                  .= 0 by A8;
  end;
