
theorem Th59:
  for C1, C2 being Coherence_Space for x being set, y being set st
  x in union C1 & y in union C2 ex f being U-linear Function of C1, C2 st
  LinTrace f = {[x,y]}
proof
  let C1, C2 be Coherence_Space;
  let a, y be set;
  assume that
A1: a in union C1 and
A2: y in union C2;
  [a,y] in [:union C1, union C2:] by A1,A2,ZFMISC_1:87;
  then reconsider X = {[a,y]} as Subset of [:union C1, union C2:] by
ZFMISC_1:31;
A3: now
    let a1,b be set;
    assume {a1,b} in C1;
    let y1,y2 be object;
    assume that
A4: [a1,y1] in X and
A5: [b,y2] in X;
    [b,y2] = [a,y] by A5,TARSKI:def 1;
    then
A6: y2 = y by XTUPLE_0:1;
    [a1,y1] = [a,y] by A4,TARSKI:def 1;
    then y1 = y by XTUPLE_0:1;
    then {y1,y2} = {y} by A6,ENUMSET1:29;
    hence {y1,y2} in C2 by A2,COH_SP:4;
  end;
  now
    let a1,b be set;
    assume {a1,b} in C1;
    let y1 be object;
    assume [a1,y1] in X & [b,y1] in X;
    then [a1,y1] = [a,y] & [b,y1] = [a,y] by TARSKI:def 1;
    hence a1 = b by XTUPLE_0:1;
  end;
  hence thesis by A3,Th56;
end;
