reserve D for non empty set,
  i,j,k,l for Nat,
  n for Nat,
  x for set,
  a,b,c,r,r1,r2 for Real,
  p,q for FinSequence of REAL,
  MR,MR1 for Matrix of REAL;

theorem Th59:
  for M being m-nonnegative Matrix of REAL holds Mx2FinS(
  Infor_FinSeq_of M) = Infor_FinSeq_of Mx2FinS(M)
proof
  let M be m-nonnegative Matrix of REAL;
  reconsider p=Mx2FinS(M) as nonnegative FinSequence of REAL by Th43;
  set pp=Infor_FinSeq_of p;
  set qq=Mx2FinS(Infor_FinSeq_of M);
  set MM=Infor_FinSeq_of M;
A1: len p = len M * width M by Th39;
A2: width MM = width M by Def8;
  len MM = len M by Def8;
  then
A3: len qq = len M * width M by A2,Th39;
  len pp = len p by Th47;
  then
A4: dom qq = dom pp by A1,A3,FINSEQ_3:29;
A5: dom qq = dom p by A1,A3,FINSEQ_3:29;
  now
    let k be Nat such that
A6: k in dom qq;
    k in Seg len qq by A6,FINSEQ_1:def 3;
    then k >= 1 by FINSEQ_1:1;
    then reconsider l = k - 1 as Nat by NAT_1:21;
    set jj=(l mod width MM)+1;
    set ii=(l div width MM)+1;
A7: [ii,jj] in Indices MM by A6,Th41;
A8: qq.k = MM*(ii,jj) by A6,Th41;
A9: p.k = M*(ii,jj) by A2,A5,A6,Th41;
    thus pp.k = p.k *log(2,p.k) by A4,A6,Th47
      .= qq.k by A7,A8,A9,Th54;
  end;
  hence thesis by A4,FINSEQ_1:13;
end;
