
theorem lift2:
for F being Field,
    E being F-algebraic FieldExtension of F
for L being F-monomorphic algebraic-closed Field,
    f being Monomorphism of F,L
ex g being Function of E,L st g is monomorphism f-extending
proof
let F be Field, E be F-algebraic FieldExtension of F;
let L be F-monomorphic algebraic-closed Field, f be Monomorphism of F,L;
set S = Ext_Set(f,E);
set R = { [p,q] where p,q is Element of S : p <= q };
   now let o be object;
     assume o in R;
     then consider p,q being Element of S such that
     A: o = [p,q] & p <= q;
     thus ex y,z being object st o = [y,z] by A;
   end; then
   reconsider R as Relation by RELAT_1:def 1;
B: field R = S
     proof
     B1: now let o be object;
         assume o in field R; then
         o in dom R \/ rng R by RELAT_1:def 6; then
         per cases by XBOOLE_0:def 3;
         suppose o in dom R; then
           consider y being object such that
           B2: [o,y] in R by XTUPLE_0:def 12;
           consider p,q being Element of S such that
           B3: [o,y] = [p,q] & p <= q by B2;
           o = p by B3,XTUPLE_0:1;
           hence o in S;
           end;
         suppose o in rng R; then
           consider y being object such that
           B2: [y,o] in R by XTUPLE_0:def 13;
           consider p,q being Element of S such that
           B3: [y,o] = [p,q] & p <= q by B2;
           o = q by B3,XTUPLE_0:1;
           hence o in S;
           end;
         end;
     now let o be object;
       assume o in S;
       then reconsider p = o as Element of S;
       p <= p by po1;
       then [p,p] in R;
       then o in dom R by XTUPLE_0:def 12;
       then o in dom R \/ rng R by XBOOLE_0:def 3;
       hence o in field R by RELAT_1:def 6;
       end;
     hence thesis by B1,TARSKI:2;
     end;
   I1: R is_reflexive_in field R
       proof
       now let x be object;
         assume x in field R;
         then reconsider p = x as Element of S by B;
         p <= p by po1;
         hence [x,x] in R;
         end;
       hence thesis by RELAT_2:def 1;
       end;
   I2: R is_transitive_in field R
       proof
       now let x,y,z be object;
         assume I3: x in field R & y in field R & z in field R &
                    [x,y] in R & [y,z] in R; then
         consider p,q being Element of S such that
         I4: [p,q] = [x,y] & p <= q;
         consider q1,r being Element of S such that
         I5: [q1,r] = [y,z] & q1 <= r by I3;
         I6: p = x & q = y & q1 = y & r = z by I4,I5,XTUPLE_0:1;
         then p <= r by I4,I5,po3;
         hence [x,z] in R by I6;
         end;
       hence thesis by RELAT_2:def 8;
       end;
   I3: R is_antisymmetric_in field R
       proof
       now let x,y be object;
         assume I3: x in field R & y in field R &
                    [x,y] in R & [y,x] in R; then
         consider p,q being Element of S such that
         I4: [p,q] = [x,y] & p <= q;
         consider q1,p1 being Element of S such that
         I5: [q1,p1] = [y,x] & q1 <= p1 by I3;
             p = x & q = y & q1 = y & p1 = x by I4,I5,XTUPLE_0:1;
         hence x = y by I4,I5,po2;
         end;
       hence thesis by RELAT_2:def 4;
       end; then
reconsider R as reflexive transitive antisymmetric Relation
   by I1,I2,RELAT_2:def 9,RELAT_2:def 16,RELAT_2:def 12;
A: R partially_orders S by I1,I2,I3,B;

now let Y be set;
  assume C1: Y c= S & R|_2 Y is being_linear-order;
  per cases;
  suppose C2: Y is empty;
    set p = the Element of S;
    thus ex x being set
         st x in S & for y being set st y in Y holds [y,x] in R
      proof
      take p;
      thus thesis by C2;
      end;
    end;
  suppose Y is non empty; then
    reconsider Y1 = Y as non empty Subset of S by C1;
    set O = R|_2 Y;
    I: O = R /\ [:Y,Y:] by WELLORD1:def 6;
    C3: field O = Y by C1,B,ORDERS_1:71;
    now let p,q be Element of Y1;
      per cases;
      suppose p = q;
        hence p <= q or q <= p by po1;
        end;
      suppose p <> q; then
        [p,q] in O or [q,p] in O by C3,C1,RELAT_2:def 14,RELAT_2:def 6; then
        per cases by I,XBOOLE_0:def 4;
        suppose [p,q] in R;
          then consider p1,q1 being Element of S such that
          C7: [p1,q1] = [p,q] & p1 <= q1;
          p1 = p & q1 = q by C7,XTUPLE_0:1;
          hence p <= q or q <= p by C7;
          end;
        suppose [q,p] in R;
          then consider q1,p1 being Element of S such that
          C7: [q1,p1] = [q,p] & q1 <= p1;
          p1 = p & q1 = q by C7,XTUPLE_0:1;
          hence p <= q or q <= p by C7;
          end;
        end;
      end;
    then reconsider Y1 as ascending non empty Subset of S by dasc;
    thus ex x being set st x in S & for y being set st y in Y holds [y,x] in R
      proof
      take p = upper_bound Y1;
      thus p in S;
      now let y be set;
        assume y in Y;
        then reconsider q = y as Element of Y1;
        q <= p by up;
        hence [y,p] in R;
        end;
      hence thesis;
      end;
    end;
  end;
then S has_upper_Zorn_property_wrt R;
then consider U being set such that Z: U is_maximal_in R by A,B,ORDERS_1:63;
reconsider U as Element of S by Z,B;

U in Ext_Set(f,E); then
consider W be Element of SubFields(E), h be Function of W,L such that
H1: U = [W,h] &
    ex W1 being FieldExtension of F, h1 being Function of W1,L
    st W1 = W & h1 = h & h1 is monomorphism f-extending;
consider W1 be FieldExtension of F, h1 be Function of W1,L such that
H2: W1 = W & h1 = h & h1 is monomorphism f-extending by H1;
reconsider W as FieldExtension of F by H2;
I1: W is Subfield of E by subfie; then
I2: the carrier of W c= the carrier of E by EC_PF_1:def 1;

now let a be Element of E;
  assume A1: not a in the carrier of W;
  reconsider E1 = E as FieldExtension of F;
  reconsider E1 as W-extending FieldExtension of F by I1,FIELD_4:7;
  reconsider E1 as W-algebraic FieldExtension of W by FIELD_7:40;
  reconsider a as W-algebraic Element of E1;
  set V = FAdj(W,{a});
  I3: V is Element of SubFields(E) by subfie;
  reconsider L1 = L as W-monomorphic algebraic-closed Field by H2,RING_3:def 3;
  reconsider h1 as Monomorphism of W,L1 by H2;
  consider r being Function of V,L such that
  A2: r is monomorphism h1-extending by lift1;
  reconsider V as W-extending FieldExtension of F;
  reconsider r as Function of V,L;
  [V,r] in S
     proof
     r is f-extending by H2,A2,e1a;
     hence thesis by I3,A2;
     end; then
  reconsider T = [V,r] as Element of S;
       U <= T by H2,H1,A2; then
  A5: [U,T] in R;
      {a} is Subset of V & a in {a} by FIELD_6:35,TARSKI:def 1;
      then the carrier of W <> the carrier of V by A1;
      then U <> T by H1,XTUPLE_0:1;
  hence contradiction by B,A5,Z;
  end; then
C: the carrier of E c= the carrier of W; then
G: the carrier of E = the carrier of W by I2,XBOOLE_0:def 10;

set E1 = the doubleLoopStr of E;
M: E1 is strict & W is strict by subfie;
D: E1 = W
   proof
   D1: the addF of E1 = (the addF of E) || the carrier of E
                     .= the addF of W by I1,G,EC_PF_1:def 1;
   D2: the multF of E1 = (the multF of E) || the carrier of E
                      .= the multF of W by I1,G,EC_PF_1:def 1;
   D3: 1.E1 = 1.E .= 1.W by I1,EC_PF_1:def 1;
       0.E1 = 0.E .= 0.W by I1,EC_PF_1:def 1;
   hence thesis by C,M,D1,D2,D3,I2,XBOOLE_0:def 10;
   end;
then reconsider h2 = h1 as Function of E1,L by H2;
E1 == E by lemug1; then
consider i being Function of E,E1 such that
E: i = id E & i is isomorphism by FIELD_7:1;
reconsider g = h2 * i as Function of E,L;
K: g is linear by E,H2,D,RINGCAT1:1;
now let a be Element of F;
   F is Subring of E by FIELD_4:def 1; then
   the carrier of F c= the carrier of E by C0SP1:def 3; then
   reconsider a1 = a as Element of E;
   g.a1 = h2.(i.a1) by E,FUNCT_1:13 .= f.a by E,H2;
   hence g.a = f.a;
   end;
then g is f-extending;
hence thesis by K;
end;
