reserve n for Nat,
  i,j for Nat,
  r,s,r1,s1,r2,s2,r9,s9 for Real,
  p,q for Point of TOP-REAL 2,
  G for Go-board,
  x,y for set,
  v for Point of Euclid 2;

theorem Th59:
  LSeg(G*(len G,width G) + |[1,1]|,G*(len G,width G) + |[1,0]|) c=
  Int cell(G,len G,width G) \/ { G*(len G,width G) + |[1,0]| }
proof
  let x be object;
  set r1 = G*(len G,1)`1, s1 = G*(1,width G)`2;
  assume
A1: x in LSeg(G*(len G,width G)+|[1,1]|,G*(len G,width G) + |[1,0]|);
  then reconsider p = x as Point of TOP-REAL 2;
  consider r such that
A2: p = (1-r)*(G*(len G,width G)+|[1,1]|)+r*(G*(len G,width G) + |[1,0]| ) and
  0<=r and
A3: r<=1 by A1;
  now
    per cases by A3,XXREAL_0:1;
    case
      r = 1;
      then p = 0.TOP-REAL 2 + 1*(G*(len G,width G) + |[1,0]|) by A2,RLVECT_1:10

        .= 1*(G*(len G,width G) + |[1,0]|) by RLVECT_1:4
        .= G*(len G,width G) + |[1,0]| by RLVECT_1:def 8;
      hence p in { G*(len G,width G) + |[1,0]| } by TARSKI:def 1;
    end;
    case
      r < 1;
      then 1 - r > 0 by XREAL_1:50;
      then
A4:   s1 < s1 +(1-r) by XREAL_1:29;
A5:   r1 < r1+1 by XREAL_1:29;
      0 <> width G by MATRIX_0:def 10;
      then
A6:   1 <= width G by NAT_1:14;
      0 <> len G by MATRIX_0:def 10;
      then
A7:   1 <= len G by NAT_1:14;
A8:   G*(len G,width G) = |[G*(len G,width G)`1,G*(len G,width G)`2]| by
EUCLID:53
        .= |[r1,G*(len G,width G)`2]| by A6,A7,GOBOARD5:2
        .= |[r1,s1]| by A6,A7,GOBOARD5:1;
A9:   Int cell(G,len G,width G) = { |[r9,s9]| : G*(len G,1)`1 < r9 & G*(1
      ,width G)`2 < s9 } by Th22;
      p = (1-r)*(G*(len G,width G))+(1-r)*|[1,1]|+r*(G* (len G,width G) +
      |[1,0]|) by A2,RLVECT_1:def 5
        .= (1-r)*(G*(len G,width G))+(1-r)*|[1,1]|+(r*(G* (len G,width G)) +
      r*|[1,0]|) by RLVECT_1:def 5
        .= r*(G*(len G,width G))+((1-r)*(G* (len G,width G))+(1-r)*|[1,1]|)
      + r*|[1,0]| by RLVECT_1:def 3
        .= r*(G*(len G,width G)) + (1-r)*(G* (len G,width G))+(1-r)*|[1,1]|
      + r*|[1,0]| by RLVECT_1:def 3
        .= (r+(1-r))*(G*(len G,width G)) +(1-r)*|[1,1]| + r*|[1,0]| by
RLVECT_1:def 6
        .= G*(len G,width G) +(1-r)*|[1,1]| + r*|[1,0]| by RLVECT_1:def 8
        .= G*(len G,width G)+|[(1-r)*1,(1-r)*1]| + r*|[1,0]| by EUCLID:58
        .= G*(len G,width G)+|[1-r,1-r]| + |[r*1,r*0]| by EUCLID:58
        .= |[r1+(1-r),s1+(1-r)]| + |[r,0]| by A8,EUCLID:56
        .= |[r1+(1-r)+r,s1+(1-r)+0]| by EUCLID:56
        .= |[r1+1,s1+(1-r)]|;
      hence p in Int cell(G,len G,width G) by A4,A5,A9;
    end;
  end;
  hence thesis by XBOOLE_0:def 3;
end;
