reserve m,n,i,i2,j for Nat,
  r,r1,r2,s,t for Real,
  x,y,z for object;
reserve p,p1,p2,p3,q,q1,q2,q3,q4 for Point of TOP-REAL n;
reserve u for Point of Euclid n;

theorem Th44:
  for W being Subset of Euclid 1,a being Real
   st W={q where q is Point of TOP-REAL 1 : ex r st q=<*r*> & r > a }
  holds W is not bounded
proof
  let W be Subset of Euclid 1,a be Real;
  assume
A1: W={q where q is Point of TOP-REAL 1 : ex r st q=<*r*> & r > a };
    |.a.|>=0 by COMPLEX1:46;
    then
A2: |.a.|+|.a.|+|.a.|>=0+|.a.| by XREAL_1:6;
    assume W is bounded;
    then consider r such that
A3: 0<r and
A4: for x,y being Point of Euclid 1 st x in W & y in W holds dist(x,y)
    <= r;
A5: (r+|.a.|)*(1.REAL 1) = (r+|.a.|)*<*1 *> by FINSEQ_2:59
      .=<*((r+|.a.|)*1)*> by RVSUM_1:47;
    reconsider z2=(r+|.a.|)*(1.REAL 1) as Point of Euclid 1
     by FINSEQ_2:131;
    a<=|.a.| & 0+|.a.|<r+|.a.| by A3,ABSVALUE:4,XREAL_1:6;
    then a<r+|.a.| by XXREAL_0:2;
    then
A6: (r+|.a.|)*(1.REAL 1) in W by A1,A5;
A7: (3*(r+|.a.|))*(1.REAL 1) = (3*(r+|.a.|))*<*1 *> by FINSEQ_2:59
      .=<*((3*(r+|.a.|))*1)*> by RVSUM_1:47;
    reconsider z1=(3*(r+|.a.|))*(1.REAL 1) as Point of Euclid 1
     by FINSEQ_2:131;
    dist(z1,z2)=|.(3*(r+|.a.|))*(1.REAL 1)-((r+|.a.|)*(1.REAL 1)).| by
JGRAPH_1:28
      .=|.((r+|.a.|)+(r+|.a.|)+(r+|.a.|)-(r+|.a.|))*(1.REAL 1).| by RLVECT_1:35
      .=|.(r+|.a.|)+(r+|.a.|).|*|.(1.REAL 1).| by TOPRNS_1:7
      .=|.(r+|.a.|)+(r+|.a.|).|*(sqrt 1) by EUCLID:73;
    then
A8: (r+|.a.|)+(r+|.a.|)<= dist(z1,z2) by ABSVALUE:4;
A9: 0<=|.a.| by COMPLEX1:46;
    then (r+|.a.|)+0<(r+|.a.|)+(r+|.a.|) by A3,XREAL_1:6;
    then
A10: (r+|.a.|)<dist(z1,z2) by A8,XXREAL_0:2;
    r+0<=r+|.a.| by A9,XREAL_1:6;
    then
A11: r<dist(z1,z2) by A10,XXREAL_0:2;
    3*r>0 by A3,XREAL_1:129;
    then a<=|.a.| & 0+|.a.|<3*r+3*|.a.| by A2,ABSVALUE:4,XREAL_1:8;
    then a<3*(r+|.a.|) by XXREAL_0:2;
    then (3*(r+|.a.|))*(1.REAL 1) in W by A1,A7;
    hence contradiction by A4,A6,A11;
end;
