reserve v,x,x1,x2,x3,x4,y,y1,y2,y3,y4,z,z1,z2 for object,
  X,X1,X2,X3,X4,Y,Y1,Y2,Y3,Y4,Y5,
  Z,Z1,Z2,Z3,Z4,Z5 for set;
reserve p for pair object;
reserve R for Relation;
reserve xx1 for Element of X1,
  xx2 for Element of X2,
  xx3 for Element of X3;
reserve xx4 for Element of X4;

theorem
  X1 c= [:X1,X2,X3,X4:] or X1 c= [:X2,X3,X4,X1:] or X1 c= [:X3,X4,X1,X2
  :] or X1 c= [:X4,X1,X2,X3:] implies X1 = {}
proof
  assume that
A1: X1 c= [:X1,X2,X3,X4:] or X1 c= [:X2,X3,X4,X1:] or X1 c= [:X3,X4,X1,
  X2:] or X1 c= [:X4,X1,X2,X3:] and
A2: X1 <> {};
A3: [:X1,X2,X3,X4:]<>{} or [:X2,X3,X4,X1:]<>{} or [:X3,X4,X1,X2:]<>{} or [:
  X4,X1,X2,X3:]<>{} by A1,A2;
   reconsider X1,X2,X3,X4 as non empty set by A3,Th39;
  per cases by A1;
  suppose
A4: X1 c= [:X1,X2,X3,X4:];
    consider v such that
A5: v in X1 and
A6: for x1,x2,x3,x4 st x1 in X1 or x2 in X1 holds v <> [x1,x2,x3,x4]
    by Th20;
    reconsider v as Element of [:X1,X2,X3,X4:] by A4,A5;
    v = [v`1_4,v`2_4,v`3_4,v`4_4];
    hence contradiction by A6;
  end;
  suppose
    X1 c= [:X2,X3,X4,X1:];
    then X1 c= [:[:X2,X3:],X4,X1:] by Th38;
    hence thesis by Th34;
  end;
  suppose
    X1 c= [:X3,X4,X1,X2:];
    then X1 c= [:[:X3,X4:],X1,X2:] by Th38;
    hence thesis by Th34;
  end;
  suppose
A7: X1 c= [:X4,X1,X2,X3:];
    consider v such that
A8: v in X1 and
A9: for x1,x2,x3,x4 st x1 in X1 or x2 in X1 holds v <> [x1,x2,x3,x4]
    by Th20;
    reconsider v as Element of [:X4,X1,X2,X3:] by A7,A8;
    v = [v`1_4,v`2_4,v`3_4,v`4_4];
    hence thesis by A9;
  end;
end;
