reserve L for satisfying_DN_1 non empty ComplLLattStr;
reserve x, y, z for Element of L;

theorem Th59:
  for L being join-commutative join-associative non empty ComplLLattStr
   st L is Robbins holds L is satisfying_DN_1
proof
  let L be join-commutative join-associative non empty ComplLLattStr;
  assume L is Robbins;
  then reconsider
  L9 = L as join-commutative join-associative Robbins non empty
  ComplLLattStr;
  let x, y, z, u be Element of L;
A1: L9 is Huntington;
  then
A2: (z + x) *' (z + x`) = z by Th58;
A3: ((x + y)` + z) *' z = (z + (x + y)`) *' z
    .= z *' (z + (x + y)`)
    .= z by A1,ROBBINS1:21;
A4: (((x + y)` + z) *' x) + z = z + (((x + y)` + z) *' x)
    .= (z + ((x + y)` + z)) *' (z + x) by A1,ROBBINS1:31
    .= (((x + y)` + z) + z) *' (z + x)
    .= ((x + y)` + (z + z)) *' (z + x) by LATTICES:def 5
    .= ((x + y)` + z) *' (z + x) by A1,ROBBINS1:12
    .= ((x` *' y`)`` + z) *' (z + x) by A1,ROBBINS1:17
    .= ((x` *' y`) + z) *' (z + x) by A1,ROBBINS1:3
    .= (z + (x` *' y`)) *' (z + x)
    .= ((z + x`) *' (z + y`)) *' (z + x) by A1,ROBBINS1:31
    .= (z + x) *' ((z + x`) *' (z + y`))
    .= (z + x) *' ((x` + z) *' (z + y`))
    .= (z + x) *' ((x` + z) *' (y` + z))
    .= (z + x) *' (x` + z) *' (y` + z) by A1,ROBBINS1:16
    .= (z + x) *' (z + x`) *' (y` + z)
    .= z *' (z + y`) by A2
    .= z by A1,ROBBINS1:21;
  (((x + y)` + z)` + (x + (z` + (z + u)`)`)`)` = (((x + y)` + z)`` *' (x +
  (z` + (z + u)`)`)``)`` by A1,ROBBINS1:17
    .= ((x + y)` + z)`` *' (x + (z` + (z + u)`)`)`` by A1,ROBBINS1:3
    .= ((x + y)` + z)`` *' (x + (z` + (z + u)`)`) by A1,ROBBINS1:3
    .= ((x + y)` + z) *' (x + (z` + (z + u)`)`) by A1,ROBBINS1:3
    .= ((x + y)`` *' z`)` *' (x + (z` + (z + u)`)`) by A1,ROBBINS1:17
    .= ((x + y) *' z`)` *' (x + (z` + (z + u)`)`) by A1,ROBBINS1:3
    .= ((x + y) *' z`)` *' (x + (z`` *' (z + u)``)``) by A1,ROBBINS1:17
    .= ((x + y) *' z`)` *' (x + (z *' (z + u)``)``) by A1,ROBBINS1:3
    .= ((x + y) *' z`)` *' (x + (z *' (z + u)``)) by A1,ROBBINS1:3
    .= ((x + y) *' z`)` *' (x + (z *' (z + u))) by A1,ROBBINS1:3
    .= ((x + y) *' z`)` *' (x + z) by A1,ROBBINS1:21
    .= (((x + y) *' z`)` *' x) + (((x + y) *' z`)` *' z) by A1,ROBBINS1:30
    .= (((x + y)`` *' z`)` *' x) + (((x + y) *' z`)` *' z) by A1,ROBBINS1:3
    .= (((x + y)` + z) *' x) + (((x + y) *' z`)` *' z) by A1,ROBBINS1:17
    .= (((x + y)` + z) *' x) + (((x + y)`` *' z`)` *' z) by A1,ROBBINS1:3
    .= z by A1,A3,A4,ROBBINS1:17;
  hence thesis;
end;
