reserve i,j,k,l,m,n for Nat,
  D for non empty set,
  f for FinSequence of D;
reserve X for compact Subset of TOP-REAL 2;
reserve r for Real;
reserve f for non trivial FinSequence of TOP-REAL 2;
reserve f for non constant standard special_circular_sequence;

theorem Th59:
  LSeg(NW-corner L~f,N-min L~f) misses LSeg(N-max L~f,NE-corner L~ f)
proof
A1: (N-min L~f)`2 = (N-max L~f)`2 by PSCOMP_1:37;
  assume LSeg(NW-corner L~f,N-min L~f) meets LSeg(N-max L~f,NE-corner L~f);
  then consider p being object such that
A2: p in LSeg(NW-corner L~f,N-min L~f) and
A3: p in LSeg(N-max L~f,NE-corner L~f) by XBOOLE_0:3;
  reconsider p as Point of TOP-REAL 2 by A2;
  (N-max L~f)`1 <= (NE-corner L~f)`1 by PSCOMP_1:38;
  then
A4: (N-max L~f)`1 <= p`1 by A3,TOPREAL1:3;
  (NW-corner L~f)`1 <= (N-min L~f)`1 by PSCOMP_1:38;
  then p`1 <= (N-min L~f)`1 by A2,TOPREAL1:3;
  then
A5: (N-min L~f)`1 >= (N-max L~f)`1 by A4,XXREAL_0:2;
  (N-min L~f)`1 <= (N-max L~f)`1 by PSCOMP_1:38;
  then (N-min L~f)`1 = (N-max L~f)`1 by A5,XXREAL_0:1;
  hence contradiction by A1,Th52,TOPREAL3:6;
end;
