reserve n for Nat,
        p,q,u,w for Point of TOP-REAL n,
        S for Subset of TOP-REAL n,
        A, B for convex Subset of TOP-REAL n,
        r for Real;

theorem Th5:
  r > 0 implies Fr cl_Ball(p,r) = Sphere(p,r)
proof
  set TR=TOP-REAL n;
  assume
A1: r>0;
  set CB=cl_Ball(p,r),B=Ball(p,r),S=Sphere(p,r);
  reconsider tr=TR as TopSpace;
  reconsider cb=CB as Subset of tr;
A2: B misses S by TOPREAL9:19;
A3: B\/S=CB by TOPREAL9:18;
A4: Int cb c=B
    proof
      reconsider ONE=1 as Real;
      let x be object;
      assume x in Int cb;
      then consider Q be Subset of TR such that
A5:     Q is open and
A6:     Q c=CB and
A7:     x in Q by TOPS_1:22;
      reconsider q=x as Point of TR by A7;
      consider w be positive Real such that
A8:     Ball(q,w)c=Q by A5,A7,TOPS_4:2;
      assume not x in B;
      then q in Sphere(p,r) by A3,A6,A7,XBOOLE_0:def 3;
      then
A9:    |.q-p.|=r by TOPREAL9:9;
      set w2=w/2;
      set wr=(w2/r)*(q-p);
A10:    |.w2/r.|=w2/r by A1,ABSVALUE:def 1;
A11:  wr+q-p = wr+(q-p) by RLVECT_1:28
            .= wr+ONE*(q-p) by RLVECT_1:def 8
            .= (w2/r+ONE)*(q-p) by RLVECT_1:def 6;
      |.wr+q-q.| = |.wr+(q-q).| by RLVECT_1:def 3
                .= |.wr+0.TR.| by RLVECT_1:15
                .= |.wr.|
                .= (w2/r)*r by A9,A10,TOPRNS_1:7
                .= w2 by A1,XCMPLX_1:87;
      then |.wr+q-q.|<w by XREAL_1:216;
      then wr+q in Ball(q,w);
      then
A12:    wr+q in Q by A8;
A13:    w2/r+ONE = w2/r+r/r by A1,XCMPLX_1:60
                .= (w2+r)/r;
A14:  w2+r>0+r by XREAL_1:6;
      |.(w2+r)/r.|=(w2+r)/r by A1,ABSVALUE:def 1;
      then |.wr+q-p.| = (w2+r)/r*r by A9,A13,A11,TOPRNS_1:7
                     .= w2+r by A1,XCMPLX_1:87;
      hence contradiction by A6,A12,A14,TOPREAL9:8;
    end;
  B c=Int cb by TOPREAL9:16,TOPS_1:24;
  then Int cb=B by A4,XBOOLE_0:def 10;
  then Fr CB=CB\B by TOPS_1:43;
  hence thesis by A3,A2,XBOOLE_1:88;
end;
