
theorem Th5:
  for T being non empty TopSpace holds the topology of T =
  FinMeetCl the topology of T
proof
  let T be non empty TopSpace;
  set X = the topology of T;
  defpred P[set] means meet $1 in the topology of T;
A1: for B9 being Element of Fin X, b being Element of X holds P[B9] implies
  P[B9 \/ {b}]
  proof
    let B9 be Element of Fin X, b be Element of X;
A2: meet {b} = b by SETFAM_1:10;
    assume
A3: meet B9 in X;
    per cases;
    suppose
      B9 <> {};
      then meet (B9 \/ {b}) = meet B9 /\ meet {b} by SETFAM_1:9;
      hence thesis by A2,A3,PRE_TOPC:def 1;
    end;
    suppose
      B9 = {};
      hence thesis by A2;
    end;
  end;
  thus the topology of T c= FinMeetCl the topology of T by Th4;
A4: P[{}.X] by PRE_TOPC:1,SETFAM_1:1;
A5: for B being Element of Fin X holds P[B] from SETWISEO:sch 4(A4,A1);
  now
    let x be Subset of T;
    assume x in FinMeetCl X;
    then consider y being Subset-Family of T such that
A6: y c=X & y is finite and
A7: x = Intersect y by Def3;
    reconsider y as Subset-Family of T;
    per cases;
    suppose
A8:   y <> {};
A9:   y in Fin X by A6,FINSUB_1:def 5;
      x = meet y by A7,A8,SETFAM_1:def 9;
      hence x in X by A5,A9;
    end;
    suppose
A10:  y = {};
      reconsider aa = {} bool the carrier of T as Subset-Family of the carrier
      of T;
      Intersect aa = the carrier of T by SETFAM_1:def 9;
      hence x in X by A7,A10,PRE_TOPC:def 1;
    end;
  end;
  hence thesis;
end;
