reserve
  X for non empty set,
  FX for Filter of X,
  SFX for Subset-Family of X;

theorem
  for X be non empty set, A be non empty Subset of X holds
  {B where B is Subset of X: A c= B} is Filter of X
  proof
    let X be non empty set, A be non empty Subset of X;
    set C={B where B is Subset of X:A c= B};
A1: C is non empty Subset-Family of X
    proof
A2: A in C;
      now
        let x be object such that
A3:     x in C;
        consider b0 be Subset of X such that
A4:     x=b0 and
        A c= b0 by A3;
        thus x in bool X by A4;
      end;
      then C c= bool X;
      hence thesis by A2;
    end;
A5: not {} in C
    proof
      assume {} in C;
      then consider b0 be Subset of X such that
A6:   {}=b0 & A c= b0;
      thus thesis by A6;
    end;
A7: for Y1,Y2 be Subset of X holds Y1 in C & Y2 in C implies Y1/\Y2 in C
    proof
      let Y1,Y2 be Subset of X such that
A8:   Y1 in C and
A9:   Y2 in C;
      consider b1 be Subset of X such that
A10:  Y1=b1 & A c= b1 by A8;
      consider b2 be Subset of X such that
A11:  Y2=b2 & A c= b2 by A9;
      A c= Y1/\Y2 by A10,A11,XBOOLE_1:19;
      hence thesis;
    end;
    for Y1,Y2 be Subset of X holds Y1 in C & Y1 c= Y2 implies Y2 in C
    proof
      let Y1,Y2 be Subset of X such that
A12:  Y1 in C and
A13:  Y1 c= Y2;
      consider b1 be Subset of X such that
A14:  b1=Y1 & A c= b1 by A12;
      A c= Y2 by A13,A14;
      hence thesis;
    end;
    hence thesis by A1,A5,A7,CARD_FIL:def 1;
  end;
