
theorem Th5:
  for C being FormalContext for O being Subset of the carrier of C
  holds O c= (AttributeDerivation(C)).((ObjectDerivation(C)).O)
proof
  let C be FormalContext;
  let O be Subset of the carrier of C;
  set A = {a where a is Attribute of C : for o being Object of C st o in O
  holds o is-connected-with a};
  for x being object holds x in A implies x in the carrier' of C
  proof
    let x be object;
    assume x in A;
    then
    ex x9 being Attribute of C st x9 = x & for o being Object of C st o in
    O holds o is-connected-with x9;
    hence thesis;
  end;
  then reconsider A as Subset of the carrier' of C by TARSKI:def 3;
  let x be object;
  assume
A1: x in O;
  then reconsider x as Object of C;
A2: for a being Attribute of C st a in A holds x is-connected-with a
  proof
    let a be Attribute of C;
    assume a in A;
    then
    ex a9 being Attribute of C st a9 = a & for o being Object of C st o in
    O holds o is-connected-with a9;
    hence thesis by A1;
  end;
  (AttributeDerivation(C)).A = {o where o is Object of C : for a being
  Attribute of C st a in A holds o is-connected-with a} by Def3;
  then x in (AttributeDerivation(C)).A by A2;
  hence thesis by Def2;
end;
