reserve h,h1,h2 for 0-convergent non-zero Real_Sequence,
  c,c1 for constant Real_Sequence,
  f,f1,f2 for PartFunc of REAL,REAL,
  x0,r,r0,r1,r2,g,g1,g2 for Real,
  n0,k,n,m for Element of NAT,
  a,b,d for Real_Sequence,
  x for set;

theorem Th5:
  f is_left_differentiable_in x0 implies f is_Lcontinuous_in x0
proof
  assume
A1: f is_left_differentiable_in x0;
A2: for a st rng a c= left_open_halfline(x0) /\ dom f & a is convergent &
  lim a = x0 holds f/*a is convergent & f.x0 = lim(f/*a)
  proof
  reconsider xx0 = x0 as Element of REAL by XREAL_0:def 1;
    set b = seq_const x0;
    let a such that
A3: rng a c= left_open_halfline(x0) /\ dom f and
A4: a is convergent and
A5: lim a = x0;
    consider r such that
A6: 0 < r and
A7: [.x0 - r, x0.] c= dom f by A1;
    consider n0 being Nat such that
A8: for k being Nat st k>=n0 holds x0 - r<a.k
        by A4,A5,A6,LIMFUNC2:1,XREAL_1:44;
    deffunc F(Nat) = a.$1-b.$1;
    consider d such that
A9: for n being Nat holds d.n = F(n) from SEQ_1:sch 1;
A10: d = a - b by A9,RFUNCT_2:1;
    then
A11: d is convergent by A4;
    reconsider c = b^\n0 as constant Real_Sequence;
A12: rng c = {x0}
    proof
      thus rng c c= {x0}
      proof
        let x be object;
        assume x in rng c;
        then consider n such that
A13:    x = (b^\n0).n by FUNCT_2:113;
        x = b.(n + n0) by A13,NAT_1:def 3;
        then x = x0 by SEQ_1:57;
        hence thesis by TARSKI:def 1;
      end;
      let x be object;
      assume x in {x0};
      then
A14:  x = x0 by TARSKI:def 1;
      c.0 = b.(0 + n0) by NAT_1:def 3
        .= x by A14,SEQ_1:57;
      hence thesis by VALUED_0:28;
    end;
A15: now
      let g be Real such that
A16:  0<g;
       reconsider n=0 as Nat;
      take n;
      let m be Nat such that
      n<=m;
A17:   m in NAT by ORDINAL1:def 12;
      x0 - r <= x0 by A6,XREAL_1:44;
      then x0 in [.x0 - r,x0.] by XXREAL_1:1;
      then rng c c= dom f by A7,A12,ZFMISC_1:31;
      then |.(f/*c).m-f.x0.| = |.f.(c.m)-f.x0.| by FUNCT_2:108,A17
        .= |.f.(b.(m+n0))-f.x0.| by NAT_1:def 3
        .= |.f.x0-f.x0.| by SEQ_1:57
        .= 0 by ABSVALUE:2;
      hence |.(f/*c).m-f.x0.|<g by A16;
    end;
    then
A18: f/*c is convergent by SEQ_2:def 6;
    lim b = b.0 by SEQ_4:26
      .= x0 by SEQ_1:57;
    then lim d = x0 - x0 by A4,A5,A10,SEQ_2:12
      .= 0;
    then
A19: lim (d^\n0) = 0 by A11,SEQ_4:20;
A20: for n holds d.n < 0 & d.n <> 0
    proof
      let n;
A21:  d.n = a.n - b.n by A9;
      a.n in rng a by VALUED_0:28;
      then a.n in left_open_halfline(x0) by A3,XBOOLE_0:def 4;
      then a.n in { r1: r1 < x0 } by XXREAL_1:229;
      then
A22:  ex r1 st r1 = a.n & r1 < x0;
      then a.n - x0 < x0 - x0 by XREAL_1:9;
      hence d.n < 0 by A21,SEQ_1:57;
      thus thesis by A21,A22,SEQ_1:57;
    end;
A23: for n being Nat holds (d^\n0).n < 0
    proof
      let n be Nat;
A24:    n+n0 in NAT by ORDINAL1:def 12;
      (d^\n0).n = d.(n + n0) by NAT_1:def 3;
      hence thesis by A20,A24;
    end;
    for n being Nat holds (d^\n0).n <>0
     by A23;
    then d ^\n0 is non-zero by SEQ_1:5;
    then reconsider h = d^\n0 as 0-convergent non-zero Real_Sequence
      by A11,A19,FDIFF_1:def 1;
A25: rng a c= dom f
    by A3,XBOOLE_0:def 4;
    now
      let n;
      thus (f/*(h+c)-f/*c+f/*c).n=(f/*(h+c)-f/*c).n+(f/*c).n by SEQ_1:7
        .= (f/*(h+c)).n-(f/*c).n+(f/*c).n by RFUNCT_2:1
        .= (f/*(h+c)).n;
    end;
    then
A26: f/*(h+c)-f/*c+(f/*c)=f/*(h+c) by FUNCT_2:63;
    now
      let n;
      thus (h+c).n=((a-b+b)^\n0).n by A10,SEQM_3:15
        .= (a-b+b).(n+n0) by NAT_1:def 3
        .= (a-b).(n+n0)+b.(n+n0) by SEQ_1:7
        .= a.(n+n0)-b.(n+n0)+b.(n+n0) by RFUNCT_2:1
        .= (a^\n0).n by NAT_1:def 3;
    end;
    then
A27: f/*(h+c)-f/*c+(f/*c)=f/*(a^\n0) by A26,FUNCT_2:63
      .= (f/*a)^\n0 by A25,VALUED_0:27;
A28: for n holds (a^\n0).n in [.x0 - r,x0.]
    proof
      let n;
      a.(n + n0) in rng a by VALUED_0:28;
      then (a^\n0).n in rng a by NAT_1:def 3;
      then (a^\n0).n in left_open_halfline(x0) by A3,XBOOLE_0:def 4;
      then (a^\n0).n in {g:g < x0} by XXREAL_1:229;
      then
A29:  ex g st g = (a^\n0).n & g < x0;
      0 <= n & 0 + n0 = n0;
      then n0 <= n0 + n by XREAL_1:6;
      then x0 - r <= a.(n + n0) by A8;
      then x0 - r <= (a^\n0).n by NAT_1:def 3;
      then (a^\n0).n in {g: x0 - r <= g & g <= x0} by A29;
      hence thesis by RCOMP_1:def 1;
    end;
    rng (h + c) c= [.x0 - r,x0.]
    proof
      let x be object;
      assume x in rng(h + c);
      then consider n such that
A30:  x = (h+c).n by FUNCT_2:113;
      (h+c).n=((a - b +b)^\n0).n by A10,SEQM_3:15
        .= (a - b + b) .(n + n0) by NAT_1:def 3
        .= (a - b).(n + n0) + b.(n + n0) by SEQ_1:7
        .= a.(n + n0) - b.(n + n0) + b.(n + n0) by RFUNCT_2:1
        .= (a^\n0).n by NAT_1:def 3;
      hence thesis by A28,A30;
    end;
    then rng (h + c) c= dom f by A7;
    then
A31: h"(#)(f/*(h+c) - f/*c) is convergent by A1,A23,A12;
    then
A32: lim (h(#)(h"(#)(f/*(h+c) - f/*c)))=0*lim(h"(#) (f/*(h+c) - f/*c)) by A19,
SEQ_2:15
      .=0;
    now
      let n;
A33:  h.n<>0 by A23;
      thus (h(#)(h"(#)(f/*(h+c) - f/*c))).n=h.n *(h"(#) (f/*(h+c) - f/*c)).n
      by SEQ_1:8
        .= h.n*((h").n*(f/*(h+c) - f/*c).n) by SEQ_1:8
        .= h.n*(((h.n)")*(f/*(h+c) - f/*c).n) by VALUED_1:10
        .= h.n*((h.n)")*(f/*(h+c) - f/*c).n
        .= 1*(f/*(h+c) - f/*c).n by A33,XCMPLX_0:def 7
        .= (f/*(h+c) - f/*c).n;
    end;
    then
A34: h(#)(h"(#)(f/*(h+c) - f/*c))=f/*(h+c)-f/*c by FUNCT_2:63;
    then
A35: f/*(h+c)-f/*c is convergent by A31;
    then
A36: f/*(h+c)-f/*c+f/*c is convergent by A18;
    hence f/*a is convergent by A27,SEQ_4:21;
    lim(f/*c)=f.x0 by A15,A18,SEQ_2:def 7;
    then lim(f/*(h+c)-f/*c+f/*c) = 0+f.x0 by A32,A34,A35,A18,SEQ_2:6
      .= f.x0;
    hence thesis by A36,A27,SEQ_4:22;
  end;
  x0 in dom f
  proof
    consider r such that
A37: 0 < r and
A38: [.x0 - r,x0.] c= dom f by A1;
    x0 - r <= x0 by A37,XREAL_1:44;
    then x0 in [.x0 - r,x0.] by XXREAL_1:1;
    hence thesis by A38;
  end;
  hence thesis by A2;
end;
