
theorem Th5:
  for T being TopStruct st {}T is closed & [#]T is closed & (for A,
B being Subset of T st A is closed & B is closed holds A \/ B is closed) & for
  F being Subset-Family of T st F is closed holds meet F is closed holds T is
  TopSpace
proof
  let T be TopStruct;
  assume that
A1: {}T is closed and
A2: [#]T is closed and
A3: for A,B being Subset of T st A is closed & B is closed holds A \/ B
  is closed and
A4: for F being Subset-Family of T st F is closed holds meet F is closed;
A5: for A,B being Subset of T st A in the topology of T & B in the topology
  of T holds A /\ B in the topology of T
  proof
    let A,B be Subset of T;
    assume that
A6: A in the topology of T and
A7: B in the topology of T;
    reconsider A, B as Subset of T;
    B is open by A7,PRE_TOPC:def 2;
    then
A8: [#]T \ B is closed by Lm2;
    A is open by A6,PRE_TOPC:def 2;
    then [#]T \ A is closed by Lm2;
    then ([#]T \ A) \/ ([#]T \ B) is closed by A3,A8;
    then [#]T \ (A /\ B) is closed by XBOOLE_1:54;
    then (A /\ B) is open by Lm2;
    hence thesis by PRE_TOPC:def 2;
  end;
A9: for G being Subset-Family of T st G c= the topology of T holds union G
  in the topology of T
  proof
    let G be Subset-Family of T;
    reconsider G9 = G as Subset-Family of T;
    assume
A10: G c= the topology of T;
    per cases;
    suppose
A11:  G = {};
      [#]T \ {}T = [#]T;
      then {}T is open by A2,Lm2;
      hence thesis by A11,PRE_TOPC:def 2,ZFMISC_1:2;
    end;
    suppose
A12:  G<>{};
      reconsider CG = COMPLEMENT(G) as Subset-Family of T;
A13:  for A being Subset of T holds A in G implies [#]T \ A is closed
         by A10,Lm2,PRE_TOPC:def 2;
      COMPLEMENT(G) is closed
      proof
        let A be Subset of T;
        assume A in COMPLEMENT(G);
        then A` in G9 by SETFAM_1:def 7;
        then [#]T \ A` is closed by A13;
        hence thesis by PRE_TOPC:3;
      end;
      then meet CG is closed by A4;
      then (union G9)` is closed by A12,TOPS_2:6;
      then [#]T \ union G is closed;
      then union G is open by Lm2;
      hence thesis by PRE_TOPC:def 2;
    end;
  end;
  [#]T \ {}T is open by A1,PRE_TOPC:def 3;
  then the carrier of T in the topology of T by PRE_TOPC:def 2;
  hence thesis by A9,A5,PRE_TOPC:def 1;
end;
