reserve p,p1,p2,q1,q2 for Point of TOP-REAL 2,
  P1,P2 for Subset of TOP-REAL 2,
  f,f1,f2,g1,g2 for FinSequence of TOP-REAL 2,
  n,m,i,j,k for Nat,
  G,G1 for Go-board,
  x,y for set;

theorem Th5:
  for f1,f2 being FinSequence of TOP-REAL 2 st f1 is one-to-one
  special & 2 <= len f1 & f2 is one-to-one special & 2 <= len f2 & X_axis(f1)
lies_between (X_axis(f1)).1, (X_axis(f1)).(len f1) & X_axis(f2) lies_between (
X_axis(f1)).1, (X_axis(f1)).(len f1) & Y_axis(f1) lies_between (Y_axis(f2)).1,
(Y_axis(f2)).(len f2) & Y_axis(f2) lies_between (Y_axis(f2)).1, (Y_axis(f2)).(
  len f2) holds L~f1 meets L~f2
proof
  let f1,f2 be FinSequence of TOP-REAL 2;
  assume that
A1: f1 is one-to-one special and
A2: 2 <= len f1 and
A3: f2 is one-to-one special and
A4: 2 <= len f2 & X_axis(f1) lies_between (X_axis(f1)).1, (X_axis(f1)).(
  len f1 ) & X_axis(f2) lies_between (X_axis(f1)).1, (X_axis(f1)).(len f1) &
  Y_axis ( f1) lies_between (Y_axis(f2)).1, (Y_axis(f2)).(len f2) & Y_axis(f2)
  lies_between (Y_axis(f2)).1, (Y_axis(f2)).(len f2);
A5: for n st n in dom f2 & n+1 in dom f2 holds f2/.n <> f2/.(n+1)
  proof
    let n;
    assume n in dom f2 & n+1 in dom f2 & f2/.n=f2/.(n+1);
    then n=n+1 by A3,PARTFUN2:10;
    hence contradiction;
  end;
  for n st n in dom f1 & n+1 in dom f1 holds f1/.n <> f1/.(n+1)
  proof
    let n;
    assume n in dom f1 & n+1 in dom f1 & f1/.n=f1/.(n+1);
    then n=n+1 by A1,PARTFUN2:10;
    hence contradiction;
  end;
  hence thesis by A1,A2,A3,A4,A5,Th4;
end;
