reserve i,j,k,i1,j1 for Nat,
  p for Point of TOP-REAL 2,
  x for set;
reserve f for non constant standard special_circular_sequence;

theorem
  for k st 1 <= k & k+2 <= len f for i,j st 1 <= i & i+2 <= len GoB f &
1 <= j & j+2 <= width GoB f & f/.(k+1) = (GoB f)*(i+1,j+1) & (f/.k = (GoB f)*(i
  ,j+1) & f/.(k+2) = (GoB f)*(i+1,j+2) or f/.(k+2) = (GoB f)*(i,j+1) & f/.k = (
GoB f)*(i+1,j+2)) holds LSeg(1/2*((GoB f)*(i+1,j)+(GoB f)*(i+2,j+1)), 1/2*((GoB
  f)*(i+1,j+1)+(GoB f)*(i+2,j+2))) misses L~f
proof
  let k such that
A1: k >= 1 and
A2: k+2 <= len f;
A3: k+1+1 = k+(1+1);
  then k+1 < len f by A2,NAT_1:13;
  then
A4: LSeg(f,k+1) c= L~f & LSeg(f,k) = LSeg(f/.k,f/.(k+1)) by A1,TOPREAL1:def 3
,TOPREAL3:19;
  1 <= k+1 by NAT_1:11;
  then
A5: LSeg(f,k+1) = LSeg(f/.(k+1),f/.(k+2)) by A2,A3,TOPREAL1:def 3;
  let i,j such that
A6: 1 <= i and
A7: i+2 <= len GoB f and
A8: 1 <= j and
A9: j+2 <= width GoB f and
A10: f/.(k+1) = (GoB f)*(i+1,j+1) and
A11: f/.k = (GoB f)*(i,j+1) & f/.(k+2) = (GoB f)*(i+1,j+2) or f/.(k+2) =
  (GoB f)*(i,j+1) & f/.k = (GoB f)*(i+1,j+2);
A12: i+1+1 = i+(1+1);
  then
A13: i+1 < len GoB f by A7,NAT_1:13;
  j < j+2 by XREAL_1:29;
  then j < width GoB f by A9,XXREAL_0:2;
  then
A14: L~f misses Int cell(GoB f,i+1,j) by A13,GOBOARD7:12;
  j+1 <= j+2 by XREAL_1:6;
  then
A15: j+1 <= width GoB f by A9,XXREAL_0:2;
  then L~f misses Int cell(GoB f,i+1,j+1) by A13,GOBOARD7:12;
  then
A16: L~f misses Int cell(GoB f,i+1,j) \/ Int cell(GoB f,i+1,j+1) by A14,
XBOOLE_1:70;
A17: 1 <= j+1 by NAT_1:11;
A18: j+1+1 = j+(1+1);
  then
A19: j+1 < width GoB f by A9,NAT_1:13;
A20: 1 <= i+1 by NAT_1:11;
  assume LSeg(1/2*((GoB f)*(i+1,j)+(GoB f)*(i+2,j+1)), 1/2*((GoB f)*(i+1,j+1
  )+(GoB f)*(i+2,j+2))) meets L~f;
  then L~f meets Int cell(GoB f,i+1,j) \/ Int cell(GoB f,i+1,j+1) \/ { 1/2*((
  GoB f)*(i+1,j+1)+(GoB f)* (i+2,j+1)) } by A8,A12,A13,A19,A20,GOBOARD6:64
,XBOOLE_1:63;
  then L~f meets { 1/2*((GoB f)*(i+1,j+1)+(GoB f)*(i+2,j+1)) } by A16,
XBOOLE_1:70;
  then consider k0 being Nat such that
  1 <= k0 and
  k0+1 <= len f and
A21: LSeg(f/.(k+1),(GoB f)*(i+2,j+1)) = LSeg(f,k0) by A7,A10,A17,A15,A12,A20,
GOBOARD7:40,ZFMISC_1:50;
  LSeg(f,k0) c= L~f & LSeg(f,k) c= L~f by TOPREAL3:19;
  hence contradiction by A6,A10,A11,A17,A13,A18,A19,A21,A4,A5,GOBOARD7:61;
end;
