reserve p, q for FinSequence,
  e,X for set,
  i, j, k, m, n for Nat,
  G for Graph;
reserve x,y,v,v1,v2,v3,v4 for Element of G;
reserve vs, vs1, vs2 for FinSequence of the carrier of G,
  c, c1, c2 for oriented Chain of G;

theorem
  vs is_oriented_vertex_seq_of c implies G-SVSet rng c c= rng vs
proof
  assume
A1: vs is_oriented_vertex_seq_of c;
  then
A2: len vs = len c + 1;
  G-SVSet rng c c= rng vs
  proof
    let y be object;
    assume y in G-SVSet rng c;
    then consider v being Element of G such that
A3: v=y and
A4: ex e being Element of the carrier' of G st e in rng c & v = (the
    Source of G).e;
    consider e being Element of the carrier' of G such that
A5: e in rng c and
A6: v = (the Source of G).e by A4;
    consider x being object such that
A7: x in dom c and
A8: e = c.x by A5,FUNCT_1:def 3;
    reconsider x as Element of NAT by A7;
A9: 1<=x by A7,FINSEQ_3:25;
A10: x<=len c by A7,FINSEQ_3:25;
    then
A11: x<=len vs by A2,NAT_1:12;
    set v1 = vs/.x;
    set v2 = vs/.(x+1);
A12: v1 = vs.x by A9,A11,FINSEQ_4:15;
    c.x orientedly_joins v1, v2 by A1,A9,A10;
    then
A13: v = v1 by A6,A8;
    x in dom vs by A9,A11,FINSEQ_3:25;
    hence thesis by A3,A12,A13,FUNCT_1:def 3;
  end;
  hence thesis;
end;
