reserve Z for RealNormSpace;
reserve a,b,c,d,e,r for Real;
reserve A,B for non empty closed_interval Subset of REAL;

theorem Th1935a:
  for X be set, f be PartFunc of REAL,the carrier of Z
    st f|X is bounded holds (r(#)f)|X is bounded
proof
   let X be set, f be PartFunc of REAL,the carrier of Z;
   assume f|X is bounded; then
   consider s be Real such that
A2: for x be set st x in dom (f|X) holds ||. (f|X)/.x .|| <s;
   reconsider p = |.r.|*|.s.|+1 as Real;
   take p;
   now let x be set;
    assume A3: x in dom ((r(#)f)|X); then
A4: x in dom (r(#)f) /\ X by RELAT_1:61;
A5: x in X & x in dom (r(#)f) by A3,RELAT_1:57; then
A6: x in X & x in dom f by VFUNCT_1:def 4; then
A7: x in dom f /\ X by XBOOLE_0:def 4;
A8: ||. (f|X)/.x .|| <s by A2,A6,RELAT_1:57;
    (r(#)f)/.x = r * (f/.x) by VFUNCT_1:def 4,A5; then
    ((r(#)f)|X)/.x = r * (f/.x) by A4,PARTFUN2:16; then
A11: ||. ( (r(#)f)|X )/.x .|| = ||. r * ((f|X)/.x) .|| by A7,PARTFUN2:16
       .= |.r.| * ||. (f|X)/.x .|| by NORMSP_1:def 1;
    0 <= |.r.| by COMPLEX1:46; then
    |.r.| * s <= |.r.| * |.s.| & |.r.| * ||. (f|X)/.x .|| <= |.r.| * s
                by A8,ABSVALUE:4,XREAL_1:64; then
    |.r.| * ||. (f|X)/.x .|| <= |.r.| * |.s.| by XXREAL_0:2;
    hence ||. ( (r(#)f)|X )/.x .|| <p by A11,XREAL_1:145;
   end;
   hence thesis;
end;
