reserve n for Nat;

theorem
  for C be compact connected non vertical non horizontal Subset of TOP-REAL 2
  for j be Nat holds
  Gauge(C,n+1)*(Center Gauge(C,n+1),j) in Lower_Arc L~Cage(C,n+1) &
  1 <= j & j <= width Gauge(C,n+1) implies
  LSeg(Gauge(C,1)*(Center Gauge(C,1),width Gauge(C,1)),
  Gauge(C,n+1)*(Center Gauge(C,n+1),j)) meets Upper_Arc L~Cage(C,n+1)
proof
  let C be compact connected non vertical non horizontal Subset of TOP-REAL 2;
  let j be Nat;
  assume that
A1: Gauge(C,n+1)*(Center Gauge(C,n+1),j) in Lower_Arc L~Cage(C,n+1) and
A2: 1 <= j and
A3: j <= width Gauge(C,n+1);
  set in1 = Center Gauge(C,n+1);
A4: n+1 >= 0+1 by NAT_1:11;
A5: 1 <= in1 by JORDAN1B:11;
A6: in1 <= len Gauge(C,n+1) by JORDAN1B:13;
A7: LSeg(Gauge(C,n+1)*(Center Gauge(C,n+1),width Gauge(C,n+1)),
  Gauge(C,n+1)*(Center Gauge(C,n+1),j)) c=
  LSeg(Gauge(C,1)*(Center Gauge(C,1),width Gauge(C,1)),
  Gauge(C,n+1)*(Center Gauge(C,n+1),j)) by A2,A3,A4,Th2;
  Lower_Arc L~Cage(C,n+1) c= L~Cage(C,n+1) by JORDAN6:61;
  hence thesis by A1,A2,A3,A5,A6,A7,Th4,XBOOLE_1:63;
end;
