reserve a, b, i, k, m, n for Nat,
  r for Real,
  D for non empty Subset of TOP-REAL 2,
  C for compact connected non vertical non horizontal Subset of TOP-REAL 2;

theorem Th5:
  for D being compact non vertical non horizontal Subset of
TOP-REAL 2 holds 2 <= m & m+1 < len Gauge(D,i) & 2 <= n & n+1 < len Gauge(D,i)
implies cell(Gauge(D,i),m,n) = cell(Gauge(D,i+1),2*m-'2,2*n-'2) \/ cell(Gauge(D
,i+1),2*m-'1,2*n-'2) \/ cell(Gauge(D,i+1),2*m-'2,2*n-'1) \/ cell(Gauge(D,i+1),2
  *m-'1,2*n-'1)
proof
  let D be compact non vertical non horizontal Subset of TOP-REAL 2;
  set I = Gauge(D,i), J = Gauge(D,i+1), z = N-bound D, e = E-bound D, s =
  S-bound D, w = W-bound D;
  assume that
A1: 2 <= m and
A2: m+1 < len I and
A3: 2 <= n and
A4: n+1 < len I;
A5: len J = width J by JORDAN8:def 1;
A6: 2*n-3 < 2*n-2 by XREAL_1:15;
  z-s >= 0 by SPRECT_1:22,XREAL_1:48;
  then (z-s)/(2|^(i+1))*(2*n-3) <= (z-s)/(2|^(i+1))*(2*n-2) by A6,XREAL_1:64;
  then
A7: s+(z-s)/(2|^(i+1))*(2*n-3) <= s+(z-s)/(2|^(i+1))*(2*n-2) by XREAL_1:6;
A8: m <= m+1 by NAT_1:11;
A9: 2*(n+1)-'2-2 = 2*n+2*1-'2-2 .= 2*n-2 by NAT_D:34;
A10: 1 <= 2*m-'2+1 by NAT_1:11;
A11: 1 <= len J by GOBRD11:34;
A12: 1 <= n by A3,XXREAL_0:2;
  then
A13: 1 <= 2*n-'1 by Lm12;
  2*n-'1 <= 2*n by NAT_D:35;
  then
A14: 1 <= 2*n by A13,XXREAL_0:2;
A15: 2*n-'1+1 = 2*n by A12,Lm12,NAT_D:43;
A16: 2*n-'1 < len J by A4,Lm15;
  then 2*n-'1+1 <= len J by NAT_1:13;
  then [1,2*n] in Indices J by A5,A15,A11,A14,MATRIX_0:30;
  then
A17: J*(1,2*n)`2 = |[w+(e-w)/(2|^(i+1))*(1-2),s+(z-s)/(2|^(i+1))*(2*n-2) ]|
  `2 by JORDAN8:def 1
    .= s+(z-s)/(2|^(i+1))*(2*n-2) by EUCLID:52;
A18: 2*m-'1 = 2*m-1 by A1,Lm8,XXREAL_0:2;
A19: 2*m-'2+1-2 = 2*m-3 by A1,Lm14;
A20: 1 <= 2*n-'2+1 by NAT_1:11;
A21: 2*m-'1 < len J by A2,Lm15;
A22: n <= n+1 by NAT_1:11;
A23: 2*n-'2+1 = 2*n-'1 by A3,Lm9,XXREAL_0:2;
A24: 2*(m+1)-'2-2 = 2*m+2*1-'2-2 .= 2*m-2 by NAT_D:34;
A25: m < len I by A2,NAT_1:13;
  then m < 2|^i + 3 by JORDAN8:def 1;
  then 2*m-'2 < 2|^(i+1) + 3 by Lm13;
  then
A26: 2*m-'2 < len J by JORDAN8:def 1;
  then 2*m-'2+1 <= len J by NAT_1:13;
  then [2*m-'2+1,1] in Indices J by A5,A11,A10,MATRIX_0:30;
  then
A27: J*(2*m-'2+1,1)`1 = |[w+(e-w)/(2|^(i+1))*(2*m-'2+1-2),s+(z-s)/(2|^(i+1))
  *(1-2)]|`1 by JORDAN8:def 1
    .= w+(e-w)/(2|^(i+1))*(2*m-'2+1-2) by EUCLID:52;
A28: 1 <= m by A1,XXREAL_0:2;
  then
A29: 1 < len I by A25,XXREAL_0:2;
  then
A30: I*(m,1)`1 = J*(2*m-'2,1)`1 by A1,A25,A11,Th3;
A31: len I = width I by JORDAN8:def 1;
  then
A32: n < width I by A4,NAT_1:13;
  then
A33: I*(1,n)`2 = J*(1,2*n-'2)`2 by A3,A31,A29,A11,Th4;
A34: 1 <= 2*m-'2 by A1,Lm11;
  then
A35: cell(J,2*m-'2,2*n-'1) = { |[r,q]| where r, q is Real:
  J*(2*m-'2,1)`1 <=
  r & r <= J* (2*m-'2+1,1)`1 & J*(1,2*n-'1)`2 <= q & q <= J*(1,2*n-'1+1)`2 }
by A5,A13,A26,A16,GOBRD11:32;
  2*m-'2 = 2*m-2 by A1,Lm7;
  then 2*m-'2 < 2*m-'1 by A18,XREAL_1:15;
  then
A36: J*(2*m-'2,1)`1 < J*(2*m-'1,1)`1 by A5,A11,A34,A21,GOBOARD5:3;
A37: 2*n-'1 = 2*n-1 by A3,Lm8,XXREAL_0:2;
A38: 2*n-'2+1-2 = 2*n-3 by A3,Lm14;
  n < 2|^i + 3 by A31,A32,JORDAN8:def 1;
  then 2*n-'2 < 2|^(i+1) + 3 by Lm13;
  then
A39: 2*n-'2 < width J by A5,JORDAN8:def 1;
  then 2*n-'2+1 <= len J by A5,NAT_1:13;
  then [1,2*n-'2+1] in Indices J by A5,A11,A20,MATRIX_0:30;
  then
A40: J*(1,2*n-'2+1)`2 = |[w+(e-w)/(2|^(i+1))*(1-2),s+(z-s)/(2|^(i+1))*(2*n-'
  2+1-2)]|`2 by JORDAN8:def 1
    .= s+(z-s)/(2|^(i+1))*(2*n-'2+1-2) by EUCLID:52;
A41: 1 <= 2*n-'2 by A3,Lm11;
  then
A42: cell(J,2*m-'2,2*n-'2) = { |[r,q]| where r, q is Real:
  J*(2*m-'2,1)`1 <=
  r & r <= J* (2*m-'2+1,1)`1 & J*(1,2*n-'2)`2 <= q & q <= J*(1,2*n-'2+1)`2 }
by A34,A26,A39,GOBRD11:32;
A43: 1 <= 2*m-'1 by A28,Lm12;
  then
A44: cell(J,2*m-'1,2*n-'2) = { |[r,q]| where r, q is Real:
  J*(2*m-'1,1)`1 <=
r & r <= J* (2*m-'1+1,1)`1 & J*(1,2*n-'2)`2 <= q & q <= J* (1,2*n-'2+1)`2 } by
A41,A39,A21,GOBRD11:32;
A45: cell(J,2*m-'1,2*n-'1) = { |[r,q]| where r, q is Real:
J*(2*m-'1,1)`1 <=
  r & r <= J* (2*m-'1+1,1)`1 & J*(1,2*n-'1)`2 <= q & q <= J*(1,2*n-'1+1)`2 }
by A5,A13,A43,A16,A21,GOBRD11:32;
A46: cell(I,m,n) = { |[r,q]| where r, q is Real:
I*(m,1)`1 <= r & r <= I*(m+
  1,1)`1 & I*(1,n)`2 <= q & q <= I*(1,n+1)`2 } by A28,A12,A25,A32,GOBRD11:32;
  1 <= n+1 by NAT_1:11;
  then [1,n+1] in Indices I by A4,A31,A29,MATRIX_0:30;
  then
A47: I*(1,n+1)`2 = |[w+(e-w)/(2|^i)*(1-2),s+(z-s)/(2|^i)*(n+1-2)]|`2 by
JORDAN8:def 1
    .= s+(z-s)/(2|^i)*(n+1-2) by EUCLID:52
    .= s+(z-s)/(2|^(i+1))*(2*(n+1)-'2-2) by A3,A22,Lm10,XXREAL_0:2;
  1 <= m+1 by NAT_1:11;
  then [m+1,1] in Indices I by A2,A31,A29,MATRIX_0:30;
  then
A48: I*(m+1,1)`1 = |[w+(e-w)/(2|^i)*(m+1-2),s+(z-s)/(2|^i)*(1-2)]|`1 by
JORDAN8:def 1
    .= w+(e-w)/(2|^i)*(m+1-2) by EUCLID:52
    .= w+(e-w)/(2|^(i+1))*(2*(m+1)-'2-2) by A1,A8,Lm10,XXREAL_0:2;
  2*n-'2 = 2*n-2 by A3,Lm7;
  then 2*n-'2 < 2*n-'1 by A37,XREAL_1:15;
  then
A49: J*(1,2*n-'2)`2 < J*(1,2*n-'1)`2 by A5,A11,A41,A16,GOBOARD5:4;
A50: 2*m-'1+1 = 2*m by A28,Lm12,NAT_D:43;
  2*m-'1 <= 2*m by NAT_D:35;
  then
A51: 1 <= 2*m by A43,XXREAL_0:2;
  2*m-'1+1 <= len J by A21,NAT_1:13;
  then [2*m,1] in Indices J by A5,A50,A11,A51,MATRIX_0:30;
  then
A52: J*(2*m,1)`1 = |[w+(e-w)/(2|^(i+1))*(2*m-2),s+(z-s)/(2|^(i+1))*(1-2) ]|
  `1 by JORDAN8:def 1
    .= w+(e-w)/(2|^(i+1))*(2*m-2) by EUCLID:52;
A53: 2*m-'2+1 = 2*m-'1 by A1,Lm9,XXREAL_0:2;
  thus cell(Gauge(D,i),m,n) c= cell(Gauge(D,i+1),2*m-'2,2*n-'2) \/ cell(Gauge(
D,i+1),2*m-'1,2*n-'2) \/ cell(Gauge(D,i+1),2*m-'2,2*n-'1) \/ cell(Gauge(D,i+1),
  2*m-'1,2*n-'1)
  proof
    let x be object;
    assume x in cell(I,m,n);
    then consider r, q being Real such that
A54: x = |[r,q]| and
A55: I*(m,1)`1 <= r and
A56: r <= I*(m+1,1)`1 and
A57: I*(1,n)`2 <= q and
A58: q <= I* (1,n+1)`2 by A46;
    r <= J*(2*m-'1,1)`1 & q <= J*(1,2*n-'1)`2 or r >= J*(2*m-'1,1)`1 & q
<= J*(1,2*n-'1)`2 or r <= J*(2*m-'1,1)`1 & q >= J*(1,2*n-'1)`2 or r >= J*(2*m-'
    1,1)`1 & q >= J*(1,2*n-'1)`2;
    then |[r,q]| in cell(J,2*m-'2,2*n-'2) or |[r,q]| in cell(J,2*m-'1,2*n-'2)
or |[r,q]| in cell(J,2*m-'2,2*n-'1) or |[r,q]| in cell(J,2*m-'1,2*n-'1) by A53
,A23,A24,A9,A50,A15,A42,A44,A35,A45,A52,A17,A48,A47,A30,A33,A55,A56,A57,A58;
    hence thesis by A54,Lm3;
  end;
  let x be object;
A59: 2*m-3 < 2*m-2 by XREAL_1:15;
  e-w >= 0 by SPRECT_1:21,XREAL_1:48;
  then (e-w)/(2|^(i+1))*(2*m-3) <= (e-w)/(2|^(i+1))*(2*m-2) by A59,XREAL_1:64;
  then
A60: w+(e-w)/(2|^(i+1))*(2*m-3) <= w+(e-w)/(2|^(i+1))*(2*m-2) by XREAL_1:6;
  assume
A61: x in cell(Gauge(D,i+1),2*m-'2,2*n-'2) \/ cell(Gauge(D,i+1),2*m-'1,2
*n-'2) \/ cell(Gauge(D,i+1),2*m-'2,2*n-'1) \/ cell(Gauge(D,i+1),2*m-'1,2*n-'1);
  per cases by A61,Lm3;
  suppose
    x in cell(Gauge(D,i+1),2*m-'2,2*n-'2);
    then consider r, q being Real such that
A62: x = |[r,q]| and
A63: J*(2*m-'2,1)`1 <= r and
A64: r <= J*(2*m-'2+1,1)`1 and
A65: J*(1,2*n-'2)`2 <= q and
A66: q <= J*(1,2*n-'2+1)`2 by A42;
A67: q <= I*(1,n+1)`2 by A38,A9,A7,A40,A47,A66,XXREAL_0:2;
    r <= I*(m+1,1)`1 by A19,A24,A60,A27,A48,A64,XXREAL_0:2;
    hence thesis by A46,A30,A33,A62,A63,A65,A67;
  end;
  suppose
    x in cell(Gauge(D,i+1),2*m-'1,2*n-'2);
    then consider r, q being Real such that
A68: x = |[r,q]| and
A69: J*(2*m-'1,1)`1 <= r and
A70: r <= J*(2*m-'1+1,1)`1 and
A71: J*(1,2*n-'2)`2 <= q and
A72: q <= J*(1,2*n-'2+1)`2 by A44;
A73: I*(m,1)`1 <= r by A30,A36,A69,XXREAL_0:2;
    q <= I*(1,n+1)`2 by A38,A9,A7,A40,A47,A72,XXREAL_0:2;
    hence thesis by A24,A50,A46,A52,A48,A33,A68,A70,A71,A73;
  end;
  suppose
    x in cell(Gauge(D,i+1),2*m-'2,2*n-'1);
    then consider r, q being Real such that
A74: x = |[r,q]| and
A75: J*(2*m-'2,1)`1 <= r and
A76: r <= J*(2*m-'2+1,1)`1 and
A77: J*(1,2*n-'1)`2 <= q and
A78: q <= J*(1,2*n-'1+1)`2 by A35;
A79: I*(1,n)`2 <= q by A33,A49,A77,XXREAL_0:2;
    r <= I*(m+1,1)`1 by A19,A24,A60,A27,A48,A76,XXREAL_0:2;
    hence thesis by A9,A15,A46,A17,A47,A30,A74,A75,A78,A79;
  end;
  suppose
    x in cell(Gauge(D,i+1),2*m-'1,2*n-'1);
    then consider r, q being Real such that
A80: x = |[r,q]| and
A81: J*(2*m-'1,1)`1 <= r and
A82: r <= J*(2*m-'1+1,1)`1 and
A83: J*(1,2*n-'1)`2 <= q and
A84: q <= J*(1,2*n-'1+1)`2 by A45;
A85: I*(1,n)`2 <= q by A33,A49,A83,XXREAL_0:2;
    I*(m,1)`1 <= r by A30,A36,A81,XXREAL_0:2;
    hence thesis by A24,A9,A50,A15,A46,A52,A17,A48,A47,A80,A82,A84,A85;
  end;
end;
