reserve C for Simple_closed_curve,
  P for Subset of TOP-REAL 2,
  p for Point of TOP-REAL 2,
  n for Element of NAT;

theorem Th5: :: P is an open south halfline
  for s,t2 being Real, P being Subset of TOP-REAL 2 st P = {
  |[ s,t ]| where t is Real : t < t2 } holds P is convex
proof
  let s,t2 be Real, P be Subset of TOP-REAL 2;
  assume
A1: P = { |[ s,t ]| where t is Real: t<t2 };
  let w1,w2 be Point of TOP-REAL 2 such that
A2: w1 in P and
A3: w2 in P;
  consider t3 being Real such that
A4: |[ s,t3 ]|=w1 and
A5: t3<t2 by A1,A2;
  consider t4 being Real such that
A6: |[ s,t4 ]|=w2 and
A7: t4<t2 by A1,A3;
A8: w2`2=t4 by A6,EUCLID:52;
  let x be object;
  assume x in LSeg(w1,w2);
  then consider l being Real such that
A9: x = (1-l)*w1 + l*w2 and
A10: 0 <= l & l <= 1;
  set w = (1-l)*w1 + l*w2;
A11: w = |[((1-l)*w1)`1+(l*w2)`1,((1-l)*w1)`2+ (l*w2)`2]| by EUCLID:55;
A12: l*w2=|[ l*w2`1 ,l*w2`2 ]| by EUCLID:57;
  then
A13: (l*w2)`1=l*w2`1 by EUCLID:52;
A14: (1-l)*w1=|[ (1-l)*w1`1 ,(1-l)*w1`2 ]| by EUCLID:57;
  then ((1-l)*w1)`1= (1-l)*w1`1 by EUCLID:52;
  then
A15: w`1=(1-l)* w1`1+ l* w2`1 by A11,A13,EUCLID:52;
  w2`1=s by A6,EUCLID:52;
  then
A16: w`1 = (1-l)*s + l*s by A4,A15,EUCLID:52
    .= s - 0;
A17: w = |[w`1, w`2]| by EUCLID:53;
A18: (l*w2)`2=l*w2`2 by A12,EUCLID:52;
  ((1-l)*w1)`2= (1-l)*w1`2 by A14,EUCLID:52;
  then
A19: w`2=(1-l)* w1`2+ l* w2`2 by A11,A18,EUCLID:52;
  w1`2=t3 by A4,EUCLID:52;
  then t2 > w`2 by A5,A7,A8,A10,A19,XREAL_1:176;
  hence thesis by A1,A9,A17,A16;
end;
