
theorem Th5:
  for X be RealNormSpace for seq be sequence of X holds seq is
Cauchy_sequence_by_Norm iff for p be Real st p > 0 holds ex n be Nat
  st for m be Nat st n <= m holds ||.seq.m-seq.n.||< p
proof
  let X be RealNormSpace;
  let seq be sequence of X;
A1: now
    assume
A2: for p be Real st p > 0 holds ex n be Nat st for m be
    Nat st n <= m holds ||.seq.m-seq.n.||< p;
    now
      let s be Real;
      reconsider ss=s as Real;
      assume 0<s;
      then consider k be Nat such that
A3:   for m be Nat st k<=m holds ||.seq.m -seq.k.||<ss/2 by A2,
XREAL_1:215;
      now
        let m,n be Nat such that
A4:     k<=m and
A5:     k<=n;
        ||.seq.n -seq.k.||<s/2 by A3,A5;
        then
A6:     ||.seq.k-seq.n.||<s/2 by NORMSP_1:7;
        ||.seq.m -seq.k.||<s/2 by A3,A4;
        then
A7:     ||.seq.m -seq.k.||+||.seq.k-seq.n.||<s/2+s/2 by A6,XREAL_1:8;
        ||.seq.m -seq.k+(seq.k-seq.n).|| <=||.seq.m -seq.k.||+||.seq.k-
seq.n.|| & ||.seq.m -seq.k+(seq.k-seq.n).|| =||.seq.m -seq.n.|| by Th3,
NORMSP_1:def 1;
        hence ||.seq.m -seq.n.|| < s by A7,XXREAL_0:2;
      end;
      hence ex k be Nat st for m,n be Nat st k <= m & k
      <=n holds ||.seq.m-seq.n.||< s;
    end;
    hence seq is Cauchy_sequence_by_Norm by RSSPACE3:8;
  end;
  now
    assume
A8: seq is Cauchy_sequence_by_Norm;
    thus for p be Real st p > 0 holds ex n be Nat st for m be
    Nat st n <= m holds ||.seq.m-seq.n.||< p
    proof
      let p be Real;
      assume p >0;
      then consider n be Nat such that
A9:   for m,k be Nat st n <= m & n <=k holds ||.seq.m-seq.k
      .||< p by A8,RSSPACE3:8;
      for m be Nat st n <= m holds ||.seq.m-seq.n.||<p by A9;
      hence thesis;
    end;
  end;
  hence thesis by A1;
end;
