reserve i,j,m,n,k for Nat,
  x,y for set,
  K for Field,
  a,L for Element of K;

theorem Th5:
  Line(Jordan_block(L,n),n) = L*Line(1.(K,n),n)
proof
  set ONE=1.(K,n);
  set Ln=Line(ONE,n);
  set J=Jordan_block(L,n);
  set LJ=Line(J,n);
  reconsider N=n as Element of NAT by ORDINAL1:def 12;
A1: width J=n by MATRIX_0:24;
A2: Indices ONE=Indices J by MATRIX_0:26;
  reconsider Ln,LJ as Element of N-tuples_on the carrier of K by MATRIX_0:24;
A3: Indices ONE=[:Seg n,Seg n:] by MATRIX_0:24;
A4: width ONE=n by MATRIX_0:24;
  now
    let j such that
A5: j in Seg n;
    n <> 0 by A5;
    then n in Seg n by FINSEQ_1:3;
    then
A6: [n,j] in [:Seg n,Seg n:] by A5,ZFMISC_1:87;
    Ln.j=ONE*(n,j) by A4,A5,MATRIX_0:def 7;
    then
A7: (L*Ln).j=L*(ONE*(n,j)) by A5,FVSUM_1:51;
A8: LJ.j=J*(n,j) by A1,A5,MATRIX_0:def 7;
    now
      per cases;
      suppose
A9:     n=j;
        hence LJ.j = L by A3,A2,A6,A8,Def1
          .= L*1_K
          .= (L*Ln).j by A3,A6,A7,A9,MATRIX_1:def 3;
      end;
      suppose
        n+1=j;
        then j>n by NAT_1:13;
        hence (L*Ln).j=LJ.j by A5,FINSEQ_1:1;
      end;
      suppose
A10:    n<>j & n+1<>j;
        hence LJ.j = 0.K by A3,A2,A6,A8,Def1
          .= L*0.K
          .= (L*Ln).j by A3,A6,A7,A10,MATRIX_1:def 3;
      end;
    end;
    hence (L*Ln).j=LJ.j;
  end;
  hence thesis by FINSEQ_2:119;
end;
