reserve k,t,i,j,m,n for Nat,
  x,y,y1,y2 for object,
  D for non empty set;
reserve K for Field,
  V for VectSp of K,
  a for Element of K,
  W for Element of V;
reserve KL1,KL2,KL3 for Linear_Combination of V,
  X for Subset of V;

theorem Th5:
  X is linearly-independent & Carrier KL1 c= X & Carrier KL2 c= X &
  Sum KL1 = Sum KL2 implies KL1 = KL2
proof
  assume that
A1: X is linearly-independent and
A2: Carrier KL1 c= X & Carrier KL2 c= X and
A3: Sum KL1 = Sum KL2;
  Sum(KL1) - Sum(KL2) = 0.V by A3,VECTSP_1:19;
  then
A4: KL1 - KL2 is Linear_Combination of Carrier(KL1 - KL2) & Sum(KL1 - KL2) =
  0.V by VECTSP_6:7,47;
A5: Carrier(KL1 - KL2) c= Carrier(KL1) \/ Carrier(KL2) by VECTSP_6:41;
  Carrier(KL1) \/ Carrier(KL2) c= X by A2,XBOOLE_1:8;
  then
A6: Carrier(KL1 - KL2) is linearly-independent by A1,A5,VECTSP_7:1,XBOOLE_1:1;
  now
    let v be Vector of V;
    not v in Carrier(KL1 - KL2) by A6,A4,VECTSP_7:def 1;
    then (KL1 - KL2).v = 0.K by VECTSP_6:2;
    then KL1.v - KL2.v = 0.K by VECTSP_6:40;
    hence KL1.v = KL2.v by RLVECT_1:21;
  end;
  hence thesis by VECTSP_6:def 7;
end;
