reserve T, T1, T2 for TopSpace,
  A, B for Subset of T,
  F, G for Subset-Family of T,
  A1 for Subset of T1,
  A2 for Subset of T2,
  TM, TM1, TM2 for metrizable TopSpace,
  Am, Bm for Subset of TM,
  Fm, Gm for Subset-Family of TM,
  C for Cardinal,
  iC for infinite Cardinal;

theorem Th5:
  weight [:T1,T2:] c= weight T1 *` weight T2
proof
  per cases;
  suppose
    T1 is empty or T2 is empty;
    hence thesis;
  end;
  suppose
A1: T1 is non empty & T2 is non empty;
    consider B2 be Basis of T2 such that
A2: card B2=weight T2 by WAYBEL23:74;
    consider B1 be Basis of T1 such that
A3: card B1=weight T1 by WAYBEL23:74;
    reconsider B12={[:a,b:] where a is Subset of T1,b is Subset of T2: a in B1
    & b in B2} as Basis of[:T1,T2:] by A1,YELLOW_9:40;
    reconsider B1,B2,B12 as non empty set by A1,YELLOW12:34;
    deffunc F(Element of[:B1,B2:])=[:$1`1,$1`2:];
A4: for x be Element of[:B1,B2:] holds F(x) is Element of B12
    proof
      let x be Element of[:B1,B2:];
      x`1 in B1 & x`2 in B2;
      then F(x) in B12;
      hence thesis;
    end;
    consider f be Function of[:B1,B2:],B12 such that
A5: for x be Element of[:B1,B2:] holds f.x=F(x) from FUNCT_2:sch 9(A4);
A6: dom f=[:B1,B2:] by FUNCT_2:def 1;
    B12 c=rng f
    proof
      let x be object;
      assume x in B12;
      then consider a be Subset of T1,b be Subset of T2 such that
A7:   x=[:a,b:] and
A8:   a in B1 & b in B2;
      reconsider ab=[a,b] as Element of[:B1,B2:] by A8,ZFMISC_1:87;
      [a,b]`1=a & [a,b]`2=b;
      then x=f.ab by A5,A7;
      hence thesis by A6,FUNCT_1:def 3;
    end;
    then
A9: weight[:T1,T2:]c=card B12 & card B12 c=card[:B1,B2:] by A6,CARD_1:12
,WAYBEL23:73;
    card[:B1,B2:]=card[:card B1,card B2:] by CARD_2:7
      .=(card B1)*`card B2 by CARD_2:def 2;
    hence thesis by A3,A2,A9;
  end;
end;
