
theorem Th5:
  for n,m being Nat st m = [\ n/2 /] & n >= 2 holds n choose m >= 2|^n / n
proof
  reconsider jj=1 as Element of REAL by XREAL_0:def 1;
  set f2a=<* jj *>;
  let n,m be Nat;
  assume
A1: m=[\ n/2 /];
  reconsider f1 = Newton_Coeff n as FinSequence of REAL;
  reconsider nm = n choose m as Element of REAL by XREAL_0:def 1;
  set f2b=(n -' 1) |-> nm;
  reconsider f2 = f2a ^ f2b ^ f2a as FinSequence of REAL;
A2: Sum f2b = (n-'1)*(n choose m) by RVSUM_1:80;
  assume
A3: n>=2;
  then
A4: n -' 1= n-1 by XREAL_1:233,XXREAL_0:2;
A5: len f2 = len (f2a ^ f2b) + len f2a by FINSEQ_1:22
    .= len (f2a ^ f2b) + 1 by FINSEQ_1:39
    .= len f2a + len f2b + 1 by FINSEQ_1:22
    .= len f2a + (n - 1) + 1 by A4,CARD_1:def 7
    .= 1 + (n - 1) + 1 by FINSEQ_1:39
    .= n+1;
  len f1 = n+1 by NEWTON:def 5;
  then dom f1 = Seg (n+1) by FINSEQ_1:def 3;
  then
A6: dom f1 = dom f2 by A5,FINSEQ_1:def 3;
A7: for i being Element of NAT st i in dom f1 holds f1.i <= f2.i
  proof
    let i be Element of NAT;
    assume
A8: i in dom f1;
    per cases by A6,A8,FINSEQ_1:25;
    suppose
A9:   i in dom (f2a ^ f2b);
      then
A10:  f2.i=(f2a^f2b).i by FINSEQ_1:def 7;
      per cases by A9,FINSEQ_1:25;
      suppose
A11:    i in dom f2a;
        set k=1-1;
        k=0;
        then reconsider k as Element of NAT;
A12:    f2.i=f2a.i by A10,A11,FINSEQ_1:def 7;
        i in Seg 1 by A11,FINSEQ_1:38;
        then
A13:    i = 1 by FINSEQ_1:2,TARSKI:def 1;
        then f1.i = n choose k by A8,NEWTON:def 5
          .= 1 by NEWTON:19;
        hence thesis by A12,A13;
      end;
      suppose
A14:    ex j be Nat st j in dom f2b & i=len f2a + j;
        set k = i-'1;
        consider j be Nat such that
A15:    j in dom f2b and
A16:    i=len f2a + j by A14;
A17:    j in Seg (n-'1) by A15,FUNCOP_1:13;
        j+1>=0+1 by XREAL_1:6;
        then i>=1 by A16,FINSEQ_1:39;
        then
A18:    k=i-1 by XREAL_1:233;
        f2.i = f2b.j by A10,A15,A16,FINSEQ_1:def 7;
        then
A19:    f2.i = n choose m by A17,FUNCOP_1:7;
        i=1+j by A16,FINSEQ_1:39;
        then -1+n<0+n & i-1<=n-1 by A4,A17,FINSEQ_1:1,XREAL_1:6;
        then
A20:    k <= n by A18,XXREAL_0:2;
        f1.i = n choose k by A8,A18,NEWTON:def 5;
        hence thesis by A1,A19,A20,Th4;
      end;
    end;
    suppose
A21:  ex j be Nat st j in dom f2a & i=len (f2a ^ f2b) + j;
      reconsider k=(n+1)-1 as Element of NAT by ORDINAL1:def 12;
      consider j be Nat such that
A22:  j in dom f2a and
A23:  i=len(f2a^f2b)+j by A21;
A24:  j in Seg 1 by A22,FINSEQ_1:38;
      then
A25:  j = 1 by FINSEQ_1:2,TARSKI:def 1;
      i = len(f2a^f2b)+1 by A23,A24,FINSEQ_1:2,TARSKI:def 1
        .= len(f2a)+len(f2b)+1 by FINSEQ_1:22
        .= len f2a + (n - 1) + 1 by A4,CARD_1:def 7
        .= 1 + (n - 1) + 1 by FINSEQ_1:39
        .= n+1;
      then
A26:  f1.i = n choose k by A8,NEWTON:def 5
        .= 1 by NEWTON:21;
      f2.i = f2a.j by A22,A23,FINSEQ_1:def 7;
      hence thesis by A25,A26;
    end;
  end;
  1<=n by A3,XXREAL_0:2;
  then
A27: n choose 1 <= n choose m by A1,Th4;
  2 <= n choose 1 by A3,NEWTON:23,XXREAL_0:2;
  then 2 <= (n choose m) by A27,XXREAL_0:2;
  then
A28: 2+(n-1)*(n choose m)<=(n choose m)+(n-1)*(n choose m) by XREAL_1:6;
A29: Sum f2 = Sum(f2a^f2b)+1 by RVSUM_1:74
    .= (1 + Sum(f2b)) +1 by RVSUM_1:76
    .= 2 + (n-'1)*(n choose m) by A2
    .= 2 + (n-1)*(n choose m) by A3,XREAL_1:233,XXREAL_0:2;
  len f1 = len f2 by A5,NEWTON:def 5;
  then Sum f1 <= Sum f2 by A7,INTEGRA5:3;
  then 2|^n <= 2 + (n-1)*(n choose m) by A29,NEWTON:32;
  then 2|^n <= n*(n choose m) by A28,XXREAL_0:2;
  then 2|^n / n <= n*(n choose m)/n by XREAL_1:72;
  hence thesis by A3,XCMPLX_1:89;
end;
