
theorem Th5:
  for A1,A2 be non empty set, B1,B2 be set ex G be Function of
  thin_cylinders(A2,B2), thin_cylinders(A1,B1) st for x be set st x in
  thin_cylinders(A2,B2) ex Bo2 being Subset of B2,Bo1 being Subset of B1, yo1
  being Function of Bo1,A1, yo2 being Function of Bo2,A2 st Bo1 is finite & Bo2
is finite & Bo1=B1 /\ Bo2 /\ (yo2"A1) & yo1=yo2 | Bo1 & x= cylinder0(A2,B2,Bo2,
  yo2) & G.x =cylinder0(A1,B1,Bo1,yo1)
proof
  let A1,A2 be non empty set, B1,B2 be set;
  defpred P[object,object] means
ex Bo2 being Subset of B2,Bo1 being Subset of B1,
  yo1 being Function of Bo1,A1, yo2 being Function of Bo2,A2 st Bo1 is finite &
Bo2 is finite & Bo1=B1 /\ Bo2 /\ (yo2"A1) & yo1=yo2 | Bo1 & $1=cylinder0(A2,B2,
  Bo2,yo2) & $2=cylinder0(A1,B1,Bo1,yo1);
A1: now
    let x be object;
    assume x in thin_cylinders(A2,B2);
    then
    ex D be Subset of Funcs(B2,A2) st x=D & D is thin_cylinder of A2,B2;
    then reconsider D2=x as thin_cylinder of A2,B2;
    consider Bo2 being Subset of B2,yo2 being Function of Bo2,A2 such that
A2: Bo2 is finite and
A3: D2=cylinder0(A2,B2,Bo2,yo2) by Def2;
    set Bo1=B1 /\ Bo2 /\ (yo2"A1);
A4: Bo1 c= B1 /\ Bo2 by XBOOLE_1:17;
    set yo1=yo2 | Bo1;
    B1 /\ Bo2 c= Bo2 by XBOOLE_1:17;
    then Bo1 c= Bo2 by A4;
    then
A5: yo1 is Function of Bo1, A2 by FUNCT_2:32;
A6: rng yo1 = yo2.: Bo1 by RELAT_1:115;
A7: yo2.: Bo1 c= yo2.: (yo2"A1) by RELAT_1:123,XBOOLE_1:17;
    yo2.: (yo2"A1) c= A1 by FUNCT_1:75;
    then yo2.: Bo1 c= A1 by A7;
    then reconsider yo1 as Function of Bo1,A1 by A5,A6,FUNCT_2:6;
    set D1= cylinder0(A1,B1,Bo1,yo1);
    B1 /\ Bo2 c= B1 by XBOOLE_1:17;
    then
A8: Bo1 c= B1 by A4;
    then
A9: D1 is thin_cylinder of A1,B1 by A2,Def2;
    reconsider D1 as object;
    take D1;
    thus D1 in thin_cylinders(A1,B1) & P[x,D1] by A2,A3,A8,A9;
  end;
  consider G be Function of thin_cylinders(A2,B2), thin_cylinders(A1,B1) such
  that
A10: for x be object st x in thin_cylinders(A2,B2) holds P[x,G.x] from
  FUNCT_2:sch 1(A1);
  take G;
  thus thesis by A10;
end;
