reserve I,J for set,i,j,x for object,
  S for non empty ManySortedSign;

theorem Th5:
  for S be non empty ManySortedSign, A be MSAlgebra-Family of I,S
  holds dom uncurry (OPER A) = [:I,the carrier' of S:]
proof
  let S be non empty ManySortedSign, A be MSAlgebra-Family of I,S;
  per cases;
  suppose
A1: I <> {};
    thus dom uncurry (OPER A) c= [:I,the carrier' of S:]
    proof
      let t be object;
      assume t in dom uncurry (OPER A);
      then consider x be object,g be Function,y be object such that
A2:   t = [x,y] and
A3:   x in dom (OPER A) and
A4:   g = (OPER A).x & y in dom g by FUNCT_5:def 2;
      reconsider x as Element of I by A3,PARTFUN1:def 2;
      ex U0 being MSAlgebra over S st U0 = A.x & (OPER A).x = the Charact
      of U0 by A1,Def11;
      then
A5:   y in the carrier' of S by A4,PARTFUN1:def 2;
      x in I by A3,PARTFUN1:def 2;
      hence thesis by A2,A5,ZFMISC_1:87;
    end;
    let x be object;
    assume
A6: x in [:I,the carrier' of S:];
    then consider y,z be object such that
A7: x = [y,z] by RELAT_1:def 1;
A8: z in the carrier' of S by A6,A7,ZFMISC_1:87;
    reconsider y as Element of I by A6,A7,ZFMISC_1:87;
    consider U0 being MSAlgebra over S such that
    U0 = A.y and
A9: (OPER A).y = the Charact of U0 by A1,Def11;
    dom (the Charact of U0) = the carrier' of S & dom (OPER A) = I by
PARTFUN1:def 2;
    hence thesis by A1,A7,A8,A9,FUNCT_5:def 2;
  end;
  suppose
A10: I = {};
    then OPER A = {};
    hence thesis by A10,FUNCT_5:43,RELAT_1:38,ZFMISC_1:90;
  end;
end;
