
theorem
  for i, j, k being Integer st k > 0 holds (i div j) div k = i div (j*k)
proof
  let i, j, k be Integer;
  set A = [\ [\ i / j /] / k /];
  set D = [\ i/(j*k) /];
  A = [\ i / j /] div k by INT_1:def 9;
  then
A1: A = (i div j) div k by INT_1:def 9;
  assume
A2: k > 0;
A3: now
    [\ i / j /] / k - 1 < A by INT_1:def 6;
    then
A4: [\ i / j /] / k < A+1 by XREAL_1:19;
    assume A < D;
    then A+1 <= D by INT_1:7;
    then [\ i / j /] / k < D by A4,XXREAL_0:2;
    then ([\ i / j /] / k) * k < D * k by A2,XREAL_1:68;
    then [\ i / j /] < D * k by A2,XCMPLX_1:87;
    then
A5: [\ i / j /] + 1 <= D * k by INT_1:7;
    [\ i/(j*k) /] <= i/(j*k) by INT_1:def 6;
    then [\ i/(j*k) /] * k <= i/(j*k) * k by A2,XREAL_1:64;
    then [\ i/(j*k) /] * k <= i/j/k * k by XCMPLX_1:78;
    then
A6: [\ i/(j*k) /] * k <= i/j by A2,XCMPLX_1:87;
    i/j - 1 < [\ i/j /] by INT_1:def 6;
    then i/j < [\ i/j /] + 1 by XREAL_1:19;
    hence contradiction by A6,A5,XXREAL_0:2;
  end;
A7: now
    [\ i/j /] <= i/j by INT_1:def 6;
    then [\ i/j /] / k <= (i/j) / k by A2,XREAL_1:72;
    then A <= [\ i / j /] / k & [\ i/j /] / k <= i/(j * k) by INT_1:def 6
,XCMPLX_1:78;
    then
A8: A <= i/(j * k) by XXREAL_0:2;
    i/(j*k)-1 < D by INT_1:def 6;
    then
A9: i/(j*k) < D+1 by XREAL_1:19;
    assume D < A;
    then D+1 <= A by INT_1:7;
    hence contradiction by A9,A8,XXREAL_0:2;
  end;
  D = i div (j*k) by INT_1:def 9;
  hence thesis by A3,A7,A1,XXREAL_0:1;
end;
