 reserve Omega for non empty set;
 reserve r for Real;
 reserve Sigma for SigmaField of Omega;
 reserve P for Probability of Sigma;

theorem Th5:
  for X be non empty set, f be PartFunc of X,REAL holds
  f to_power 2 = (-f) to_power 2 &
  f to_power 2 = (abs(f)) to_power 2
  proof
    let X be non empty set, f be PartFunc of X,REAL;
    dom (-f) = dom f by VALUED_1:8;
    then dom((-f) to_power 2)= dom f by MESFUN6C:def 4;
    then A1:dom(f to_power 2)= dom((-f) to_power 2) by MESFUN6C:def 4;
    dom abs f = dom f by VALUED_1:def 11;
    then A2:dom((abs f) to_power 2)= dom f by MESFUN6C:def 4;
    then A3:
    dom(f to_power 2)= dom((abs(f)) to_power 2) by MESFUN6C:def 4;
    for x be Element of X st x in dom(f to_power 2)
    holds (f to_power 2).x=((-f) to_power 2).x&
    (f to_power 2).x =((abs(f)) to_power 2).x
    proof
      let x be Element of X;
      assume A4: x in dom(f to_power 2);
      then A5: x in dom((-f) to_power 2) &
      x in dom(f to_power 2) & x in dom f & x in dom (-f) &
      x in dom((abs(f)) to_power 2) by A2,A1,MESFUN6C:def 4;
      A6: ((-f) to_power 2).x = (((-f).x) to_power 2)
      by A4,A1,MESFUN6C:def 4
      .= ((-(f.x)) to_power 2) by VALUED_1:8
      .= ((f.x) to_power 2) by FIB_NUM3:3
      .=(f to_power 2).x by A4,MESFUN6C:def 4;
      ((abs(f)) to_power 2).x = (f to_power 2).x
      proof
        A7: ((abs(f)) to_power 2).x = ((abs(f)).x) to_power 2
        by A5,MESFUN6C:def 4
        .= |.f.x qua Complex.| to_power 2 by VALUED_1:18;
        now per cases by A7,ABSVALUE:1;
          case ((abs(f)) to_power 2).x = (f.x) to_power 2;
            hence thesis by A4,MESFUN6C:def 4;
          end;
          case ((abs(f)) to_power 2).x = (-(f.x)) to_power 2; then
            ((abs(f)) to_power 2).x =((f.x) to_power 2) by FIB_NUM3:3
            .=(f to_power 2).x by A4,MESFUN6C:def 4;
            hence thesis;
          end;
        end;
        hence thesis;
      end;
      hence thesis by A6;
    end;then
    (for x be Element of X st x in dom(f to_power 2)
    holds (f to_power 2).x=((-f) to_power 2).x)&
    (for x be Element of X st x in dom(f to_power 2) holds
    (f to_power 2).x =((abs(f)) to_power 2).x);
    hence thesis by A1,A3,PARTFUN1:5;
  end;
