reserve x,y,y1,y2 for set,
  p for FinSequence,
  i,k,l,n for Nat,
  V for RealLinearSpace,
  u,v,v1,v2,v3,w for VECTOR of V,
  a,b for Real,
  F,G,H1,H2 for FinSequence of V,
  A,B for Subset of V,
  f for Function of the carrier of V, REAL;

theorem
  for V being Abelian add-associative right_zeroed right_complementable
non empty addLoopStr, F,G,H being FinSequence of the carrier of V st len F =
len G & len F = len H & (for k st k in dom F holds H.k = F/.k - G/.k) holds Sum
  (H) = Sum(F) - Sum(G)
proof
  let V be Abelian add-associative right_zeroed right_complementable non
  empty addLoopStr, F,G,H be FinSequence of the carrier of V;
  assume that
A1: len F = len G and
A2: len F = len H and
A3: for k st k in dom F holds H.k = F/.k - G/.k;
  deffunc Q(set)= - G/.$1;
  consider I being FinSequence such that
A4: len I = len G and
A5: for k be Nat st k in dom I holds I.k = Q(k) from FINSEQ_1:sch 2;
  dom I = Seg len G by A4,FINSEQ_1:def 3;
  then
A6: dom G = Seg len G & for k st k in Seg len G holds I.k = Q(k) by A5,
FINSEQ_1:def 3;
  rng I c= the carrier of V
  proof
    let x be object;
    assume x in rng I;
    then consider y being object such that
A7: y in dom I and
A8: I.y = x by FUNCT_1:def 3;
    reconsider y as Element of NAT by A7;
    x = - G/.y by A5,A7,A8;
    then reconsider v = x as Element of V;
    v in V;
    hence thesis;
  end;
  then reconsider I as FinSequence of the carrier of V by FINSEQ_1:def 4;
A9: now
    let k;
    assume
A10: k in dom F;
A11: dom F = Seg len F & dom I = Seg len I by FINSEQ_1:def 3;
    then
A12: I.k = I/.k by A1,A4,A10,PARTFUN1:def 6;
    thus H.k = F/.k - G/.k by A3,A10
      .= F/.k + I/.k by A1,A4,A5,A11,A10,A12;
  end;
  Sum(I) = - Sum(G) by A4,A6,Th4;
  hence thesis by A1,A2,A4,A9,Th2;
end;
