reserve x for Int_position,
  n,p0 for Nat;
reserve P,Q,V for Instruction-Sequence of SCMPDS;

theorem Th5:
  for s being 0-started State of SCMPDS,I being halt-free shiftable Program
  of SCMPDS, a,x,y be Int_position, i,c be Integer st s.x >= c+s.
DataLoc(s.a,i) &
(for t be 0-started State of SCMPDS,Q st t.x >= c+t.DataLoc(s.a,i) & t.y=s
.y & t.a=s.a & t.DataLoc(s.a,i) > 0
 holds IExec(I,Q,t).a=t.a & I is_closed_on t,Q &
I is_halting_on t,Q & IExec(I,Q,t).DataLoc(s.a,i) < t.DataLoc(s.a,i)
 & IExec(I,Q,t).x
  >= c+IExec(I,Q,t).DataLoc(s.a,i) & IExec(I,Q,t).y=t.y)
 holds while>0(a,i,I) is_closed_on s,P & while>0(a,i,I) is_halting_on s,P &
 (s.DataLoc(s.a,i) > 0 implies
  IExec(while>0(a,i,I),P,s)
   =IExec(while>0(a,i,I),P,Initialize IExec(I,P,s)))
proof
  let s be 0-started State of SCMPDS,
      I be halt-free shiftable Program of SCMPDS, a,x1,
  y1 be Int_position, i,c be Integer;
  set b=DataLoc(s.a,i);
  assume s.x1 >= c+s.b;
  then
A1: for x st x in {x1} holds s.x >= c+s.b by TARSKI:def 1;
  assume
A2: for t be 0-started State of SCMPDS,Q st t.x1 >= c+t.b &
 t.y1=s.y1 & t.a=s.a & t.b > 0
  holds IExec(I,Q,t).a=t.a & I is_closed_on t,Q & I is_halting_on t,Q
 & IExec(I,Q,t).b < t.b & IExec(I,Q,t).x1 >= c+IExec(I,Q,t).b &
  IExec(I,Q,t).y1=t.y1;
  now
    let t be 0-started State of SCMPDS, Q;
    assume that
A3: for x st x in {x1} holds t.x >= c+t.b and
A4: for x st x in {y1} holds t.x=s.x and
A5: t.a=s.a and
A6: t.b > 0;
    y1 in {y1} by TARSKI:def 1;
    then
A7: t.y1=s.y1 by A4;
    x1 in {x1} by TARSKI:def 1;
    then
A8: t.x1 >= c+t.b by A3;
    hence
    IExec(I,Q,t).a=t.a & I is_closed_on t,Q
     & I is_halting_on t,Q & IExec(I,Q,t).
    b < t.b by A2,A5,A6,A7;
    hereby
      let x;
      assume
A9:  x in {x1};
      IExec(I,Q,t).x1 >= c+IExec(I,Q,t).b
       by A2,A5,A6,A8,A7;
      hence IExec(I,Q,t).x >= c+IExec(I,Q,t).b
       by A9,TARSKI:def 1;
    end;
      let x;
      assume
A10:  x in {y1};
      hence IExec(I,Q,t).x=IExec(I,Q,t).y1
       by TARSKI:def 1
        .=t.y1 by A2,A5,A6,A8,A7
        .=t.x by A10,TARSKI:def 1;
  end;
  hence thesis by A1,SCMPDS_8:27;
end;
