reserve X for set;
reserve S for Subset-Family of X;

theorem V:
  for S be cap-finite-partition-closed Subset-Family of X holds
  for A,B be finite Subset of S st A is mutually-disjoint &
  B is mutually-disjoint ex P be finite Subset of S st
  P is a_partition of union A /\ union B
  proof
    let S be cap-finite-partition-closed Subset-Family of X;
    let A,B be finite Subset of S;
    assume that
A1: A is mutually-disjoint and
A2: B is mutually-disjoint;
    per cases;
    suppose
A3:   [:A,B:]<>{};
      defpred F[object,object] means
      ex a,b be set st a in A & b in B & $1=[a,b] &
      ex p be finite Subset of S st p is a_partition of a/\b &
      $2=p;
      set XIN = the set of all s where s is Element of [:A,B:];
      set XOUT={s where s is finite Subset of S:ex a,b be set st
      a in A & b in B & s is a_partition of a/\b};
A4:   for x be object st x in XIN ex y be object st y in XOUT & F[x,y]
      proof
        let x be object;
        assume x in XIN;
        then consider s be Element of [:A,B:] such that
A5:     x=s;
        consider a0,b0 be object such that
A6:     a0 in A & b0 in B and
A7:     s=[a0,b0] by A3,ZFMISC_1:def 2;
        reconsider a0,b0 as set by TARSKI:1;
        per cases;
        suppose a0/\b0 is non empty;
          then consider P be finite Subset of S such that
A8:       P is a_partition of a0/\b0 by A6,Defcap;
          P in XOUT by A6,A8;
          hence thesis by A5,A6,A7,A8;
        end;
        suppose a0/\b0 is empty;
          then
A9:       {} is finite Subset of S & {} is a_partition of a0/\b0
          by SUBSET_1:1,EQREL_1:45;
          then {} in XOUT by A6;
          hence thesis by A5,A6,A7,A9;
        end;
      end;
      consider f be Function such that
A10:  dom f = XIN & rng f c= XOUT and
A11:  for x be object st x in XIN holds F[x,f.x] from FUNCT_1:sch 6(A4);
A12:  Union f is finite
      proof
A13:    [:A,B:]=XIN
        proof
A14:      [:A,B:] c= XIN
          proof
            let x be object;
            assume x in [:A,B:];
            hence thesis;
          end;
          XIN c= [:A,B:]
          proof
            let x be object;
            assume x in XIN;
            then consider s be Element of [:A,B:] such that
A15:        s=x;
            thus thesis by A3,A15;
          end;
          hence thesis by A14;
        end;
        for z be set st z in rng f holds z is finite
        proof
          let z be set;
          assume z in rng f;
          then z in XOUT by A10;
          then consider s0 be finite Subset of S such that
A16:      s0=z and
          ex a,b be set st a in A & b in B & s0 is a_partition of a/\b;
          thus thesis by A16;
        end;
        hence thesis by A13,A10,FINSET_1:8,FINSET_1:7;
      end;
A17:  Union f c= S
      proof
        let x be object;
        assume x in Union f;
        then consider y be set such that
A18:    x in y & y in rng f by TARSKI:def 4;
        y in XOUT by A18,A10;
        then consider s0 be finite Subset of S such that
A19:    y=s0 and
        ex a,b be set st a in A & b in B & s0 is a_partition of a/\b;
        thus thesis by A18,A19;
      end;
A20:  Union f c= bool (union A /\ union B)
      proof
        let x be object;
        assume x in Union f;
        then consider y be set such that
A21:    x in y and
A22:    y in rng f by TARSKI:def 4;
        y in XOUT by A22,A10;
        then consider s0 be finite Subset of S such that
A23:    y=s0 and
A24:    ex a,b be set st a in A & b in B & s0 is a_partition of a/\b;
        reconsider x as set by TARSKI:1;
        consider a0, b0 be set such that
A25:    a0 in A & b0 in B and
A26:    s0 is a_partition of a0/\b0 by A24;
        a0 c= union A & b0 c= union B by A25,ZFMISC_1:74;
        then a0/\b0 c= union A /\ union B by XBOOLE_1:27;
        then x c= union A /\ union B by XBOOLE_1:1,A21,A23,A26;
        hence thesis;
      end;
A27:  union Union f = union A /\ union B
      proof
A28:    union Union f c= union A /\ union B
        proof
          union Union f c= union bool (union A /\ union B) by A20,ZFMISC_1:77;
          hence thesis by ZFMISC_1:81;
        end;
        union A/\union B c= union Union f
        proof
          let x be object;
          assume x in union A/\union B; then
A29:      x in union A & x in union B by XBOOLE_0:def 4;
          then consider a be set such that
A30:      x in a & a in A by TARSKI:def 4;
          consider b be set such that
A31:      x in b & b in B by A29,TARSKI:def 4;
          [a,b] in [:A,B:] by A30,A31,ZFMISC_1:def 2;
          then
A32:      [a,b] in XIN;
          then F[[a,b],f.([a,b])] by A11;
          then consider a0,b0 be set such that
          a0 in A & b0 in B and
A33:      [a,b]=[a0,b0] and
A34:      ex p be finite Subset of S st p is a_partition of a0/\b0 &
          f.([a0,b0])=p;
          consider p be finite Subset of S such that
A35:      p is a_partition of a0/\b0 and
A36:      f.([a0,b0])=p by A34;
A37:      a0=a & b0=b by A33,XTUPLE_0:1;
          f.([a,b]) in rng f by A32,A10,FUNCT_1:def 3;
          then
A38:      union (f.([a,b])) c= union union rng f by ZFMISC_1:77,ZFMISC_1:74;
          x in a/\b by A30,A31,XBOOLE_0:def 4;
          then x in union (f.([a,b])) by A35,A36,A37,EQREL_1:def 4;
          hence thesis by A38;
        end;
        hence thesis by A28;
      end;
      for u be Subset of union A /\ union B st u in Union f holds
      u<>{} &
      for v be Subset of union A /\ union B st v in Union f holds u=v or
      u misses v
      proof
        let u be Subset of union A /\ union B;
        assume u in Union f;
        then consider v be set such that
A39:    u in v and
A40:    v in rng f by TARSKI:def 4;
        consider w be object such that
A41:    w in dom f and
A42:    v=f.w by A40,FUNCT_1:def 3;
        consider x be Element of [:A,B:] such that
A43:    w=x by A41,A10;
        reconsider w as Element of [:A,B:] by A43;
        consider wa,wb be object such that
        wa in A & wb in B and
A44:    w=[wa,wb] by A3,ZFMISC_1:def 2;
        consider a,b be set such that
A45:    a in A & b in B and
A46:    [wa,wb]=[a,b] and
A47:    ex p be finite Subset of S st p is a_partition of a/\b &
        f.w=p by A41,A10,A11,A44;
        consider p be finite Subset of S such that
A48:    p is a_partition of a/\b and
A49:    f.w=p by A47;
        v in XOUT by A40,A10;
        then consider s0 be finite Subset of S such that
A50:    v=s0 and
A51:    ex a,b be set st a in A & b in B & s0 is a_partition of a/\b;
        consider a0,b0 be set such that
        a0 in A & b0 in B and
A52:    s0 is a_partition of a0/\b0 by A51;
        thus u<>{} by A39,A50,A52;
        thus for v be Subset of union A /\ union B st v in Union f holds
        u=v or u misses v
        proof
          let jw be Subset of union A /\ union B;
          assume jw in Union f;
          then consider lw0 be set such that
A53:      jw in lw0 and
A54:      lw0 in rng f by TARSKI:def 4;
          consider lw be object such that
A55:      lw in dom f and
A56:      lw0=f.lw by A54,FUNCT_1:def 3;
          consider lx be Element of [:A,B:] such that
A57:      lw=lx by A55,A10;
          reconsider lw as Element of [:A,B:] by A57;
          consider lwa,lwb be object such that
          lwa in A & lwb in B and
A58:      lw=[lwa,lwb] by A3,ZFMISC_1:def 2;
          consider la,lb be set such that
A59:      la in A & lb in B and
A60:      [lwa,lwb]=[la,lb] and
A61:      ex p be finite Subset of S st p is a_partition of la/\lb &
          f.lw=p by A55,A10,A11,A58;
          consider lp be finite Subset of S such that
A62:      lp is a_partition of la/\lb and
A63:      f.lw=lp by A61;
          per cases;
          suppose a=la & b=lb;
            hence thesis
            by A39,A42,A44,A46,A56,A58,A60,A63,A62,A53,EQREL_1:def 4;
          end;
          suppose
A64:        a<>la or b<>lb;
            a/\b c= b & la/\lb c= lb & a/\b c= a & la/\lb c= la by XBOOLE_1:17;
            then
            a/\b misses la/\lb by A64,A45,A59,A1,A2,TAXONOM2:def 5,XBOOLE_1:64;
            hence thesis by A39,A49,A48,A42,A56,A63,A62,A53,XBOOLE_1:64;
          end;
        end;
      end;
      then Union f is a_partition of union A /\ union B
      by A20,A27,EQREL_1:def 4;
      hence thesis by A12,A17;
    end;
    suppose [:A,B:]={};
      then A={} or B={};
      hence thesis by ZFMISC_1:2,EQREL_1:45;
    end;
  end;
