reserve y,w for set;
reserve T for non empty TopSpace;

theorem Th5:
  for T,T1 being non empty TopSpace,f being continuous Function of
  T,T1 holds T1 is T_1 implies {f"{z} where z is Element of T1 : z in rng f} is
a_partition of the carrier of T & for A being Subset of T st A in {f"{z} where
  z is Element of T1 : z in rng f} holds A is closed
proof
  let T,T1 be non empty TopSpace;
  let f be continuous Function of T,T1;
  assume
A1: T1 is T_1;
A2: dom f = the carrier of T by FUNCT_2:def 1;
  thus {f"{z} where z is Element of T1 : z in rng f} is a_partition of the
  carrier of T
  proof
    {f"{z} where z is Element of T1 : z in rng f} c= bool the carrier of T
    proof
      let y be object;
      assume y in {f"{z} where z is Element of T1 : z in rng f};
      then ex z being Element of T1 st y = f"{z} & z in rng f;
      hence thesis;
    end;
    then reconsider fz = {f"{z} where z is Element of T1 : z in rng f} as
    Subset-Family of T;
    reconsider fz as Subset-Family of T;
A3: for A being Subset of T st A in fz holds A <> {} & for B being Subset
    of T st B in fz holds A = B or A misses B
    proof
      let A be Subset of T;
      assume A in fz;
      then consider z being Element of T1 such that
A4:   A = f"{z} and
A5:   z in rng f;
      consider y being object such that
A6:   y in dom f & z = f.y by A5,FUNCT_1:def 3;
      f.y in {f.y} by TARSKI:def 1;
      hence A <> {} by A4,A6,FUNCT_1:def 7;
      let B be Subset of T;
      assume B in fz;
      then consider w being Element of T1 such that
A7:   B = f"{w} and
      w in rng f;
      now
        assume not A misses B;
        then consider v being object such that
A8:     v in A and
A9:     v in B by XBOOLE_0:3;
        f.v in {z} by A4,A8,FUNCT_1:def 7;
        then
A10:    f.v = z by TARSKI:def 1;
        f.v in {w} by A7,A9,FUNCT_1:def 7;
        hence A = B by A4,A7,A10,TARSKI:def 1;
      end;
      hence A = B or A misses B;
    end;
    the carrier of T c= union fz
    proof
      let y be object;
      consider z being set such that
A11:  z = f.y;
      assume
A12:  y in the carrier of T;
      then
A13:  z in rng f by A2,A11,FUNCT_1:def 3;
      then reconsider z as Element of T1;
A14:  f"{z} in fz by A13;
      f.y in {f.y} by TARSKI:def 1;
      then y in f"{z} by A2,A12,A11,FUNCT_1:def 7;
      hence thesis by A14,TARSKI:def 4;
    end;
    then union fz = the carrier of T;
    hence thesis by A3,EQREL_1:def 4;
  end;
  thus for A being Subset of T st A in {f"{z} where z is Element of T1 : z in
  rng f} holds A is closed
  proof
    let A be Subset of T;
    assume A in {f"{z} where z is Element of T1 : z in rng f};
    then consider z being Element of T1 such that
A15: A = f"{z} and
    z in rng f;
    {z} is closed by A1,URYSOHN1:19;
    hence thesis by A15,PRE_TOPC:def 6;
  end;
end;
