reserve M for non empty MetrSpace,
  c,g1,g2 for Element of M;
reserve N for non empty MetrStruct,
  w for Element of N,
  G for Subset-Family of N,
  C for Subset of N;
reserve R for Reflexive non empty MetrStruct;
reserve T for Reflexive symmetric triangle non empty MetrStruct,
  t1 for Element of T,
  Y for Subset-Family of T,
  P for Subset of T;
reserve f for Function,
  n,m,p,n1,n2,k for Nat,
  r,s,L for Real,
  x,y for set;
reserve S1 for sequence of M,
  S2 for sequence of N;

theorem Th5:
  N is triangle symmetric & S2 is convergent implies S2 is Cauchy
proof
  assume that
A1: N is triangle and
A2: N is symmetric;
   reconsider N as symmetric non empty MetrStruct by A2;
  assume
A3:  S2 is convergent;
  reconsider S2 as sequence of N;
  consider g being Element of N such that
A4: for r st 0<r ex n st for m st n<=m holds dist(S2.m,g)<r by A3;
  let r;
  assume 0<r;
  then consider n such that
A5: for m st n<=m holds dist(S2.m,g)<r/2 by A4,XREAL_1:215;
  take n;
  let m,m9 be Nat;
  assume that
A6: m>=n and
A7: m9>=n;
A8: dist(S2.m9,g)<r/2 by A5,A7;
  dist(S2.m,g)<r/2 by A5,A6;
  then
A9: dist(S2.m,g)+dist(g,S2.m9)<r/2+r/2 by A8,XREAL_1:8;
  dist(S2.m,S2.m9)<=dist(S2.m,g)+dist(g,S2.m9) by A1,METRIC_1:4;
  hence thesis by A9,XXREAL_0:2;
end;
