reserve T for non empty TopSpace,
  A, B for Subset of T,
  F, G for Subset-Family of T;

theorem Th5:
  density T c= weight T
proof
  defpred P[set] means $1 <> {};
  deffunc F(set) = the Element of $1;
  set B = the Basis of T;
  consider B1 being Basis of T such that
  B1 c= B and
A1: card B1 = weight T by TOPGEN_2:18;
  set A = { F(BB) where BB is Element of bool the carrier of T : BB in B1 & P[
  BB] };
  A c= the carrier of T
  proof
    let x be object;
    assume x in A;
    then consider B2 being Subset of T such that
A2: x = the Element of B2 and
    B2 in B1 and
A3: B2 <> {};
    x in B2 by A2,A3;
    hence thesis;
  end;
  then reconsider A as Subset of T;
  for Q being Subset of T st Q <> {} & Q is open holds A meets Q
  proof
    let Q be Subset of T;
    assume Q <> {} & Q is open;
    then consider W being Subset of T such that
A4: W in B1 and
A5: W c= Q and
A6: W <> {} by Th4;
    the Element of W in A & the Element of W in W by A4,A6;
    hence thesis by A5,XBOOLE_0:3;
  end;
  then A is dense by TOPS_1:45;
  then
A7: density T c= card A by TOPGEN_1:def 12;
  card { F(w) where w is Element of bool the carrier of T : w in B1 & P[w
  ] } c= card B1 from BORSUK_2:sch 1;
  hence thesis by A1,A7;
end;
