reserve Al for QC-alphabet;
reserve a,b,c,d for object,
  i,j,k,m,n for Nat,
  p,q,r for Element of CQC-WFF(Al),
  x,y,y0 for bound_QC-variable of Al,
  X for Subset of CQC-WFF(Al),
  A for non empty set,
  J for interpretation of Al,A,
  v,w for Element of Valuations_in(Al,A),
  Sub for CQC_Substitution of Al,
  f,f1,g,h,h1 for FinSequence of CQC-WFF(Al);
reserve fin,fin1 for FinSequence;
reserve PR,PR1 for FinSequence of [:set_of_CQC-WFF-seq(Al),Proof_Step_Kinds:];
reserve a for Element of A;

theorem Th59:
  still_not-bound_in <*p*> = still_not-bound_in p
proof
A1: now
    1 in Seg 1 by FINSEQ_1:2,TARSKI:def 1;
    then
A2: 1 in dom <*p*> by FINSEQ_1:38;
A3: p = <*p*>.1;
    let b be object;
    assume b in still_not-bound_in p;
    hence b in still_not-bound_in <*p*> by A2,A3,Def5;
  end;
  now
    let b be object;
    assume b in still_not-bound_in <*p*>;
    then consider i,q such that
A4: i in dom <*p*> and
A5: q = <*p*>.i & b in still_not-bound_in q by Def5;
    i in Seg 1 by A4,FINSEQ_1:38;
    then i = 1 by FINSEQ_1:2,TARSKI:def 1;
    hence b in still_not-bound_in p by A5;
  end;
  hence thesis by A1,TARSKI:2;
end;
