reserve x,y for set,
  i for Nat;
reserve V for non empty CLSStruct,
  u,v,v1,v2,v3 for VECTOR of V,
  A for Subset of V,
  l, l1, l2 for C_Linear_Combination of A,
  x,y,y1,y2 for set,
  a,b for Complex,
  F for FinSequence of the carrier of V,
  f for Function of the carrier of V, COMPLEX;
reserve K,L,L1,L2,L3 for C_Linear_Combination of V;
reserve e,e1,e2 for Element of C_LinComb V;

theorem Th59:
  for V being Abelian add-associative vector-distributive scalar-distributive
  scalar-associative scalar-unital non
empty CLSStruct, M1,M2 being Subset of V, z1,z2 being Complex st M1 is convex
  & M2 is convex holds z1*M1 + z2*M2 is convex
proof
  let V be Abelian add-associative vector-distributive scalar-distributive
  scalar-associative scalar-unital non empty
  CLSStruct;
  let M1,M2 be Subset of V;
  let z1,z2 be Complex;
  assume that
A1: M1 is convex and
A2: M2 is convex;
  let u,v be VECTOR of V;
  let s be Complex;
  assume that
A3: ex p being Real st s=p & 0 < p & p < 1 and
A4: u in z1*M1 + z2*M2 and
A5: v in z1*M1 + z2*M2;
  consider v1,v2 be VECTOR of V such that
A6: v = v1 + v2 and
A7: v1 in z1*M1 and
A8: v2 in z2*M2 by A5;
  consider u1,u2 be VECTOR of V such that
A9: u = u1 + u2 and
A10: u1 in z1*M1 and
A11: u2 in z2*M2 by A4;
  consider y1 be VECTOR of V such that
A12: v1 = z1*y1 and
A13: y1 in M1 by A7;
  consider x1 be VECTOR of V such that
A14: u1 = z1*x1 and
A15: x1 in M1 by A10;
A16: s*u1 + (1r-s)*v1 = z1*s*x1 + (1r-s)*(z1*y1) by A14,A12,CLVECT_1:def 4
    .= z1*s*x1 + z1*(1r-s)*y1 by CLVECT_1:def 4
    .= z1*(s*x1) + z1*(1r-s)*y1 by CLVECT_1:def 4
    .= z1*(s*x1) + z1*((1r-s)*y1) by CLVECT_1:def 4
    .= z1*(s*x1 + (1r-s)*y1) by CLVECT_1:def 2;
  consider y2 be VECTOR of V such that
A17: v2 = z2*y2 and
A18: y2 in M2 by A8;
  consider x2 be VECTOR of V such that
A19: u2 = z2*x2 and
A20: x2 in M2 by A11;
A21: s*u2 + (1r-s)*v2 = z2*s*x2 + (1r-s)*(z2*y2) by A19,A17,CLVECT_1:def 4
    .= z2*s*x2 + z2*(1r-s)*y2 by CLVECT_1:def 4
    .= z2*(s*x2) + z2*(1r-s)*y2 by CLVECT_1:def 4
    .= z2*(s*x2) + z2*((1r-s)*y2) by CLVECT_1:def 4
    .= z2*(s*x2 + (1r-s)*y2) by CLVECT_1:def 2;
  s*x2 + (1r-s)*y2 in M2 by A2,A3,A20,A18;
  then
A22: s*u2 + (1r-s)*v2 in z2*M2 by A21;
  s*x1 + (1r-s)*y1 in M1 by A1,A3,A15,A13;
  then
A23: s*u1 + (1r-s)*v1 in z1*M1 by A16;
  s*(u1+u2) + (1r-s)*(v1+v2) = s*u1 + s*u2 + (1r-s)*(v1+v2) by CLVECT_1:def 2
    .= s*u1 + s*u2 + ((1r-s)*v1 + (1r-s)*v2) by CLVECT_1:def 2
    .= s*u1 + s*u2 + (1r-s)*v1 + (1r-s)*v2 by RLVECT_1:def 3
    .= s*u1 + (1r-s)*v1 + s*u2 + (1r-s)*v2 by RLVECT_1:def 3
    .= s*u1 + (1r-s)*v1 + (s*u2 + (1r-s)*v2) by RLVECT_1:def 3;
  hence thesis by A9,A6,A23,A22;
end;
