reserve D for non empty set,
  i,j,k,l for Nat,
  n for Nat,
  x for set,
  a,b,c,r,r1,r2 for Real,
  p,q for FinSequence of REAL,
  MR,MR1 for Matrix of REAL;

theorem Th60:
  for p,q being ProbFinS FinSequence of REAL for M being Matrix of
  REAL st M=(ColVec2Mx p)*(LineVec2Mx q) holds SumAll Infor_FinSeq_of M = Sum
  Infor_FinSeq_of p+Sum Infor_FinSeq_of q
proof
  let p,q be ProbFinS FinSequence of REAL;
  set p1= Infor_FinSeq_of p;
  set p2= (Sum Infor_FinSeq_of q)*p;
A1: len p1 = len p by Th47;
  dom p2 = dom p by VALUED_1:def 5;
  then
A2: len p1 = len p2 by A1,FINSEQ_3:29;
  len FinSeq_log(2,q) = len q by Def6;
  then
A3: len mlt(q,FinSeq_log(2,q)) = len q by MATRPROB:30;
  let M be Matrix of REAL such that
A4: M=(ColVec2Mx p)*(LineVec2Mx q);
  reconsider M as Joint_Probability Matrix of REAL by A4,Th23;
  set M1 = Infor_FinSeq_of M;
  set L = LineSum M1;
A5: len L = len M1 by MATRPROB:def 1;
  then
A6: dom L = dom M1 by FINSEQ_3:29;
A7: len M1 = len M by Def8;
  then
A8: dom M1 = dom M by FINSEQ_3:29;
A9: len M = len p by A4,Th22;
  then
A10: dom M = dom p by FINSEQ_3:29;
A11: now
    let k such that
A12: k in dom L;
    reconsider pp=Line(M,k) as nonnegative FinSequence of REAL by A6,A8,A12
,Th19;
A13: pp = p.k * q by A4,A6,A8,A12,Th22;
    dom (p.k*log(2,p.k)*q) = dom q by VALUED_1:def 5;
    then
A14: len (p.k*log(2,p.k)*q) = len q by FINSEQ_3:29;
    dom (p.k*mlt(q,FinSeq_log(2,q))) = dom mlt(q,FinSeq_log(2,q)) by
VALUED_1:def 5;
    then
A15: len (p.k*log(2,p.k)*q) = len (p.k*mlt(q,FinSeq_log(2,q))) by A3,A14,
FINSEQ_3:29;
A16: p.k>=0 by A6,A8,A10,A12,Def1;
    thus L.k = Sum(M1.k) by A12,MATRPROB:def 1
      .= Sum(Line(M1,k)) by A6,A12,MATRIX_0:60
      .= Sum(Infor_FinSeq_of pp) by A6,A8,A12,Th53
      .= Sum((p.k*log(2,p.k)*q)+(p.k*mlt(q,FinSeq_log(2,q)))) by A13,A16,Th51
      .= Sum(p.k*log(2,p.k)*q)+Sum(p.k*mlt(q,FinSeq_log(2,q))) by A15,
INTEGRA5:2
      .= p.k*log(2,p.k)*Sum q+Sum(p.k*mlt(q,FinSeq_log(2,q))) by RVSUM_1:87
      .= p.k*log(2,p.k)*1+Sum(p.k*mlt(q,FinSeq_log(2,q))) by MATRPROB:def 5
      .= p.k*log(2,p.k)+p.k*Sum Infor_FinSeq_of q by RVSUM_1:87;
  end;
A17: dom p1 = dom L by A9,A7,A5,A1,FINSEQ_3:29;
  now
    let k such that
A18: k in dom p1;
    thus L.k = p.k*log(2,p.k)+p.k*Sum Infor_FinSeq_of q by A11,A17,A18
      .= p1.k + p.k*Sum Infor_FinSeq_of q by A18,Th47
      .= p1.k + p2.k by RVSUM_1:44;
  end;
  then Sum L = Sum p1 + Sum p2 by A9,A7,A5,A1,A2,Th7
    .= Sum p1 + (Sum Infor_FinSeq_of q)*Sum p by RVSUM_1:87
    .= Sum p1 + (Sum Infor_FinSeq_of q)*1 by MATRPROB:def 5
    .= Sum Infor_FinSeq_of p+Sum Infor_FinSeq_of q;
  hence thesis by MATRPROB:def 3;
end;
