
theorem lift3b:
for F being Field,
    E being FieldExtension of F,
    L being F-homomorphic E-homomorphic Field
for f being Homomorphism of F,L for g being Homomorphism of E,L
st g is f-extending holds (Image f) is Subfield of (Image g)
proof
let F be Field, E be FieldExtension of F,
    L be F-homomorphic E-homomorphic Field;
let f be Homomorphism of F,L; let g be Homomorphism of E,L;
assume AS: g is f-extending;
set If = Image f, Ig = Image g;
H1: rng f = the carrier of If &
    rng g = the carrier of Ig by RING_2:def 6;
    F is Subfield of E by FIELD_4:7; then
H3: the carrier of F c= the carrier of E by EC_PF_1:def 1;
A: the carrier of If c= the carrier of Ig
   proof
   now let o be object;
     assume o in the carrier of If;
     then consider u being object such that
     A1: u in dom f & f.u = o by H1,FUNCT_1:def 3;
     reconsider a = u as Element of F by A1;
     reconsider a1 = a as Element of E by H3;
     A2: dom g = the carrier of E by FUNCT_2:def 1;
     g.a1 = o by AS,A1;
     hence o in the carrier of Ig by H1,A2,FUNCT_1:def 3;
     end;
   hence thesis;
   end;
H4: [:the carrier of If,the carrier of If:] c=
    [:the carrier of Ig,the carrier of Ig:] by A,ZFMISC_1:96;
B: the addF of If
        = (the addF of L) || the carrier of If by EC_PF_1:def 1
       .= ((the addF of L) || the carrier of Ig) || the carrier of If
          by H4,FUNCT_1:51
       .= (the addF of Ig) || the carrier of If by EC_PF_1:def 1;
C: the multF of If
        = (the multF of L) || the carrier of If by EC_PF_1:def 1
       .= ((the multF of L) || the carrier of Ig) || the carrier of If
          by H4,FUNCT_1:51
       .= (the multF of Ig) || the carrier of If by EC_PF_1:def 1;
D: 1.If = 1.L by RING_2:def 6 .= 1.Ig by RING_2:def 6;
   0.If = 0.L by RING_2:def 6 .= 0.Ig by RING_2:def 6;
hence thesis by A,B,C,D,EC_PF_1:def 1;
end;
