
theorem Th60:
  for G being _finite _Graph, H being Subgraph of G st G.size() = H.size()
  ex p being non empty _finite Graph-yielding FinSequence
  st p.1 == H & p.len p = G & len p = G.order() - H.order() + 1 &
    for n being Element of dom p st n <= len p - 1 holds
    ex v being Vertex of G
    st p.(n+1) is addVertex of p.n, v & not v in the_Vertices_of p.n
proof
  let G be _finite _Graph, H be Subgraph of G;
  assume A1: G.size() = H.size();
  set V = the_Vertices_of G \ the_Vertices_of H;
  G is addVertices of H, V by A1, Th34;
  then consider p being non empty Graph-yielding FinSequence such that
    A2: p.1 == H & p.len p = G & len p = card (V \ the_Vertices_of H) + 1 and
    A3: for n being Element of dom p st n <= len p - 1 holds
      ex v being Vertex of G
      st p.(n+1) is addVertex of p.n, v & not v in the_Vertices_of p.n by Th59;
  defpred P[Nat] means for n being Element of dom p st $1 = n
    holds p.n is _finite;
  A4: P[1] by A2, GLIB_000:89;
  A5: for k being non zero Nat st P[k] holds P[k+1]
  proof
    let k be non zero Nat;
    assume A6: P[k];
    let m be Element of dom p;
    assume A7: k+1 = m;
    then A8: k+1 <= len p by FINSEQ_3:25;
    then A9: k+1-1 <= len p - 0 by XREAL_1:13;
    1 <= k by NAT_1:14;
    then reconsider n = k as Element of dom p by A9, FINSEQ_3:25;
    k+1-1 <= len p - 1 by A8, XREAL_1:9;
    then consider v being Vertex of G such that
      A10: p.(n+1) is addVertex of p.n, v & not v in the_Vertices_of p.n by A3;
    p.n is _finite by A6;
    hence thesis by A7, A10;
  end;
  A11: for k being non zero Nat holds P[k] from NAT_1:sch 10(A4,A5);
  for x being Element of dom p holds p.x is _finite
  proof
    let x be Element of dom p;
    x is non zero Nat by FINSEQ_3:25;
    hence thesis by A11;
  end;
  then reconsider p as non empty _finite Graph-yielding FinSequence
    by GLIB_000:def 66;
  take p;
  thus p.1 == H & p.len p = G by A2;
  V \ the_Vertices_of H = the_Vertices_of G \
      (the_Vertices_of H \/ the_Vertices_of H) by XBOOLE_1:41
    .= the_Vertices_of G \ the_Vertices_of H;
  hence len p = card (the_Vertices_of G) - card(the_Vertices_of H) + 1
      by A2, CARD_2:44
    .= G.order() - card(the_Vertices_of H) + 1 by GLIB_000:def 24
    .= G.order() - H.order() + 1 by GLIB_000:def 24;
  thus thesis by A3;
end;
