reserve n for Nat,
  i,j for Nat,
  r,s,r1,s1,r2,s2,r9,s9 for Real,
  p,q for Point of TOP-REAL 2,
  G for Go-board,
  x,y for set,
  v for Point of Euclid 2;

theorem Th60:
  LSeg(G*(1,1) - |[1,1]|,G*(1,1) - |[0,1]|) c= Int cell(G,0,0) \/
  { G*(1,1) - |[0,1]| }
proof
  let x be object;
  set r1 = G*(1,1)`1, s1 = G*(1,1)`2;
  assume
A1: x in LSeg(G*(1,1)-|[1,1]|,G*(1,1) - |[0,1]|);
  then reconsider p = x as Point of TOP-REAL 2;
  consider r such that
A2: p = (1-r)*(G*(1,1)-|[1,1]|)+r*(G*(1,1) - |[0,1]|) and
  0<=r and
A3: r<=1 by A1;
  now
    per cases by A3,XXREAL_0:1;
    case
      r = 1;
      then p = 0.TOP-REAL 2 + 1*(G*(1,1) - |[0,1]|) by A2,RLVECT_1:10
        .= 1*(G*(1,1) - |[0,1]|) by RLVECT_1:4
        .= G*(1,1) - |[0,1]| by RLVECT_1:def 8;
      hence p in { G*(1,1) - |[0,1]| } by TARSKI:def 1;
    end;
    case
      r < 1;
      then 1 - r > 0 by XREAL_1:50;
      then r1 < r1+(1-r) by XREAL_1:29;
      then
A4:   r1-(1-r) < r1 by XREAL_1:19;
A5:   G*(1,1) = |[r1,s1]| by EUCLID:53;
      s1 < s1 +1 by XREAL_1:29;
      then
A6:   s1-1 < s1 by XREAL_1:19;
A7:   Int cell(G,0,0) = { |[r9,s9]| : r9 < G*(1,1)`1 & s9 < G* (1,1)`2 }
      by Th18;
      p = (1-r)*(G*(1,1))-(1-r)*|[1,1]|+r*(G*(1,1) - |[0,1]|) by A2,RLVECT_1:34
        .= (1-r)*(G*(1,1))-(1-r)*|[1,1]|+(r*(G*(1,1)) - r*|[0,1]|) by
RLVECT_1:34
        .= r*(G*(1,1)) + ((1-r)*(G*(1,1))-(1-r)*|[1,1]|) - r*|[0,1]| by
RLVECT_1:def 3
        .= r*(G*(1,1)) + (1-r)*(G*(1,1))-(1-r)*|[1,1]| - r*|[0,1]| by
RLVECT_1:def 3
        .= (r+(1-r))*(G*(1,1)) -(1-r)*|[1,1]| - r*|[0,1]| by RLVECT_1:def 6
        .= G*(1,1) -(1-r)*|[1,1]| - r*|[0,1]| by RLVECT_1:def 8
        .= G*(1,1)-|[(1-r)*1,(1-r)*1]| - r*|[0,1]| by EUCLID:58
        .= G*(1,1)-|[1-r,1-r]| - |[r*0,r*1]| by EUCLID:58
        .= |[r1-(1-r),s1-(1-r)]| - |[0,r]| by A5,EUCLID:62
        .= |[r1-(1-r)-0,s1-(1-r)-r]| by EUCLID:62
        .= |[r1-(1-r),s1-1]|;
      hence p in Int cell(G,0,0) by A6,A4,A7;
    end;
  end;
  hence thesis by XBOOLE_0:def 3;
end;
