reserve a for Real;
reserve p,q for Point of TOP-REAL 2;

theorem Th60:
  for cn being Real, K0,B0 being Subset of TOP-REAL 2,f being
Function of (TOP-REAL 2)|K0,(TOP-REAL 2)|B0 st -1<cn & cn<1 & f=(cn-FanMorphN)|
  K0 & B0=NonZero TOP-REAL 2 & K0={p: p`2>=0 & p<>0.TOP-REAL 2} holds f is
  continuous
proof
  let cn be Real,K0,B0 be Subset of TOP-REAL 2,
f be Function of (TOP-REAL 2)|
  K0,(TOP-REAL 2)|B0;
  set sn=sqrt(1-cn^2);
  set p0=|[cn,sn]|;
A1: p0`2=sn by EUCLID:52;
  assume
A2: -1<cn & cn<1 & f=(cn-FanMorphN)|K0 & B0=NonZero TOP-REAL 2 & K0={p:
  p`2>=0 & p<>0.TOP-REAL 2};
  then cn^2<1^2 by SQUARE_1:50;
  then
A3: 1-cn^2>0 by XREAL_1:50;
  then
A4: p0`2>0 by A1,SQUARE_1:25;
  then p0 in K0 by A2,JGRAPH_2:3;
  then reconsider K1=K0 as non empty Subset of TOP-REAL 2;
  p0<>0.TOP-REAL 2 by A1,A3,JGRAPH_2:3,SQUARE_1:25;
  then not p0 in {0.TOP-REAL 2} by TARSKI:def 1;
  then reconsider D=B0 as non empty Subset of TOP-REAL 2 by A2,XBOOLE_0:def 5;
A5: the carrier of (TOP-REAL 2)|K1 = K1 by PRE_TOPC:8;
  p0`1=cn by EUCLID:52;
  then
A6: |.p0.|=sqrt((sn)^2+cn^2) by A1,JGRAPH_3:1;
A7: D<>{};
  sn^2=1-cn^2 by A3,SQUARE_1:def 2;
  then
A8: p0`1/|.p0.|=cn by A6,EUCLID:52;
  then
A9: p0 in {p: p`1/|.p.|>=cn & p`2>=0 & p<>0.TOP-REAL 2} by A4,JGRAPH_2:3;
A10: {p: p`1/|.p.|<=cn & p`2>=0 & p<>0.TOP-REAL 2} c= K1
  proof
    let x be object;
    assume x in {p: p`1/|.p.|<=cn & p`2>=0 & p<>0.TOP-REAL 2};
    then ex p st p=x & p`1/|.p.|<=cn & p`2>=0 & p<>0.TOP-REAL 2;
    hence thesis by A2;
  end;
A11: {p: p`1/|.p.|>=cn & p`2>=0 & p<>0.TOP-REAL 2} c= K1
  proof
    let x be object;
    assume x in {p: p`1/|.p.|>=cn & p`2>=0 & p<>0.TOP-REAL 2};
    then ex p st p=x & p`1/|.p.|>=cn & p`2>=0 & p<>0.TOP-REAL 2;
    hence thesis by A2;
  end;
  then reconsider
  K00={p: p`1/|.p.|>=cn & p`2>=0 & p<>0.TOP-REAL 2} as non empty
  Subset of ((TOP-REAL 2)|K1) by A9,PRE_TOPC:8;
  the carrier of (TOP-REAL 2)|D =D by PRE_TOPC:8;
  then
A12: rng (f|K00) c=D;
  p0 in {p: p`1/|.p.|<=cn & p`2>=0 & p<>0.TOP-REAL 2} by A4,A8,JGRAPH_2:3;
  then reconsider
  K11={p: p`1/|.p.|<=cn & p`2>=0 & p<>0.TOP-REAL 2} as non empty
  Subset of ((TOP-REAL 2)|K1) by A10,PRE_TOPC:8;
  the carrier of (TOP-REAL 2)|D =D by PRE_TOPC:8;
  then
A13: rng (f|K11) c=D;
  the carrier of (TOP-REAL 2)|B0=the carrier of (TOP-REAL 2)|D;
  then
A14: dom f=the carrier of (TOP-REAL 2)|K1 by FUNCT_2:def 1
    .=K1 by PRE_TOPC:8;
  then dom (f|K00)=K00 by A11,RELAT_1:62
    .= the carrier of ((TOP-REAL 2)|K1)|K00 by PRE_TOPC:8;
  then reconsider
  f1=f|K00 as Function of ((TOP-REAL 2)|K1)|K00,(TOP-REAL 2)|D by A12,FUNCT_2:2
;
  dom (f|K11)=K11 by A10,A14,RELAT_1:62
    .= the carrier of ((TOP-REAL 2)|K1)|K11 by PRE_TOPC:8;
  then reconsider
  f2=f|K11 as Function of ((TOP-REAL 2)|K1)|K11,(TOP-REAL 2)|D by A13,FUNCT_2:2
;
  defpred P[Point of TOP-REAL 2] means $1`1/|.$1.|>=cn & $1`2>=0 & $1<>0.
  TOP-REAL 2;
A15: dom f2=the carrier of ((TOP-REAL 2)|K1)|K11 by FUNCT_2:def 1
    .=K11 by PRE_TOPC:8;
  {p: P[p]} is Subset of TOP-REAL 2 from DOMAIN_1:sch 7;
  then reconsider
  K001={p: p`1/|.p.|>=cn & p`2>=0 & p<>0.TOP-REAL 2} as non empty
  Subset of (TOP-REAL 2) by A9;
A16: the carrier of (TOP-REAL 2)|K1 =K1 by PRE_TOPC:8;
  defpred P[Point of TOP-REAL 2] means $1`1>=(cn)*(|.$1.|) & $1`2>=0;
  {p: P[p]} is Subset of TOP-REAL 2 from DOMAIN_1:sch 7;
  then reconsider
  K003={p: p`1>=(cn)*(|.p.|) & p`2>=0} as Subset of (TOP-REAL 2);
  defpred P[Point of TOP-REAL 2] means $1`1/|.$1.|<=cn & $1`2>=0 & $1<>0.
  TOP-REAL 2;
A17: {p: P[p]} is Subset of TOP-REAL 2 from DOMAIN_1:sch 7;
A18: rng ((cn-FanMorphN)|K001) c= K1
  proof
    let y be object;
    assume y in rng ((cn-FanMorphN)|K001);
    then consider x being object such that
A19: x in dom ((cn-FanMorphN)|K001) and
A20: y=((cn-FanMorphN)|K001).x by FUNCT_1:def 3;
    x in dom (cn-FanMorphN) by A19,RELAT_1:57;
    then reconsider q=x as Point of TOP-REAL 2;
A21: y=(cn-FanMorphN).q by A19,A20,FUNCT_1:47;
    dom ((cn-FanMorphN)|K001)=(dom (cn-FanMorphN))/\ K001 by RELAT_1:61
      .=(the carrier of TOP-REAL 2)/\ K001 by FUNCT_2:def 1
      .=K001 by XBOOLE_1:28;
    then
A22: ex p2 being Point of TOP-REAL 2 st p2=q & p2`1/|.p2.|>= cn & p2`2>=0 &
    p2<>0.TOP-REAL 2 by A19;
    then
A23: (q`1/|.q.|-cn)>= 0 by XREAL_1:48;
    |.q.|<>0 by A22,TOPRNS_1:24;
    then
A24: (|.q.|)^2>0^2 by SQUARE_1:12;
    set q4= |[ |.q.|* ((q`1/|.q.|-cn)/(1-cn)), |.q.|*( sqrt(1-((q`1/|.q.|-cn)/
    (1-cn))^2))]|;
A25: q4`1= |.q.|* ((q`1/|.q.|-cn)/(1-cn)) by EUCLID:52;
A26: 1-cn>0 by A2,XREAL_1:149;
    0<=(q`2)^2 by XREAL_1:63;
    then 0+(q`1)^2<=(q`1)^2+(q`2)^2 by XREAL_1:7;
    then (q`1)^2 <= (|.q.|)^2 by JGRAPH_3:1;
    then (q`1)^2/(|.q.|)^2 <= (|.q.|)^2/(|.q.|)^2 by XREAL_1:72;
    then (q`1)^2/(|.q.|)^2 <= 1 by A24,XCMPLX_1:60;
    then ((q`1)/|.q.|)^2 <= 1 by XCMPLX_1:76;
    then 1>=q`1/|.q.| by SQUARE_1:51;
    then 1-cn>=q`1/|.q.|-cn by XREAL_1:9;
    then -(1-cn)<= -( q`1/|.q.|-cn) by XREAL_1:24;
    then (-(1-cn))/(1-cn)<=(-( q`1/|.q.|-cn))/(1-cn) by A26,XREAL_1:72;
    then -1<=(-( q`1/|.q.|-cn))/(1-cn) by A26,XCMPLX_1:197;
    then ((-(q`1/|.q.|-cn))/(1-cn))^2<=1^2 by A26,A23,SQUARE_1:49;
    then
A27: 1-((-(q`1/|.q.|-cn))/(1-cn))^2>=0 by XREAL_1:48;
    then
A28: 1-(-((q`1/|.q.|-cn))/(1-cn))^2>=0 by XCMPLX_1:187;
    sqrt(1-((-(q`1/|.q.|-cn))/(1-cn))^2)>=0 by A27,SQUARE_1:def 2;
    then sqrt(1-(-(q`1/|.q.|-cn))^2/(1-cn)^2)>=0 by XCMPLX_1:76;
    then sqrt(1-(q`1/|.q.|-cn)^2/(1-cn)^2)>=0;
    then
A29: sqrt(1-((q`1/|.q.|-cn)/(1-cn))^2)>=0 by XCMPLX_1:76;
A30: q4`2= |.q.|*( sqrt(1-((q`1/|.q.|-cn)/(1-cn))^2)) by EUCLID:52;
    then
A31: (q4`2)^2= (|.q.|)^2*( sqrt(1-((q`1/|.q.|-cn)/(1-cn))^2))^2
      .= (|.q.|)^2*(1-((q`1/|.q.|-cn)/(1-cn))^2) by A28,SQUARE_1:def 2;
    (|.q4.|)^2=(q4`1)^2+(q4`2)^2 by JGRAPH_3:1
      .=(|.q.|)^2 by A25,A31;
    then
A32: q4<>0.TOP-REAL 2 by A24,TOPRNS_1:23;
    cn-FanMorphN.q= |[ |.q.|* ((q`1/|.q.|-cn)/(1-cn)), |.q.|*( sqrt(1-((q
    `1/|.q.|-cn)/(1-cn))^2))]| by A2,A22,Th51;
    hence thesis by A2,A21,A30,A29,A32;
  end;
A33: dom (cn-FanMorphN)=the carrier of TOP-REAL 2 by FUNCT_2:def 1;
  then dom ((cn-FanMorphN)|K001)=K001 by RELAT_1:62
    .= the carrier of (TOP-REAL 2)|K001 by PRE_TOPC:8;
  then reconsider
  f3=(cn-FanMorphN)|K001 as Function of (TOP-REAL 2)|K001,(TOP-REAL
  2)|K1 by A5,A18,FUNCT_2:2;
A34: K003 is closed by Th58;
  K1 c= D
  proof
    let x be object;
    assume
A35: x in K1;
    then ex p6 being Point of TOP-REAL 2 st p6=x & p6`2>=0 & p6 <>0.TOP-REAL 2
    by A2;
    then not x in {0.TOP-REAL 2} by TARSKI:def 1;
    hence thesis by A2,A35,XBOOLE_0:def 5;
  end;
  then D=K1 \/ D by XBOOLE_1:12;
  then
A36: (TOP-REAL 2)|K1 is SubSpace of (TOP-REAL 2)|D by TOPMETR:4;
  p0 in {p: p`1/|.p.|<=cn & p`2>=0 & p<>0.TOP-REAL 2} by A4,A8,JGRAPH_2:3;
  then reconsider
  K111={p: p`1/|.p.|<=cn & p`2>=0 & p<>0.TOP-REAL 2} as non empty
  Subset of TOP-REAL 2 by A17;
A37: rng ((cn-FanMorphN)|K111) c= K1
  proof
    let y be object;
    assume y in rng ((cn-FanMorphN)|K111);
    then consider x being object such that
A38: x in dom ((cn-FanMorphN)|K111) and
A39: y=((cn-FanMorphN)|K111).x by FUNCT_1:def 3;
    x in dom (cn-FanMorphN) by A38,RELAT_1:57;
    then reconsider q=x as Point of TOP-REAL 2;
A40: y=(cn-FanMorphN).q by A38,A39,FUNCT_1:47;
    dom ((cn-FanMorphN)|K111)=(dom (cn-FanMorphN))/\ K111 by RELAT_1:61
      .=(the carrier of TOP-REAL 2)/\ K111 by FUNCT_2:def 1
      .=K111 by XBOOLE_1:28;
    then
A41: ex p2 being Point of TOP-REAL 2 st p2=q & p2`1/|.p2.|<= cn & p2`2>=0 &
    p2<>0.TOP-REAL 2 by A38;
    then
A42: (q`1/|.q.|-cn)<=0 by XREAL_1:47;
    |.q.|<>0 by A41,TOPRNS_1:24;
    then
A43: (|.q.|)^2>0^2 by SQUARE_1:12;
    set q4= |[ |.q.|* ((q`1/|.q.|-cn)/(1+cn)), |.q.|*( sqrt(1-((q`1/|.q.|-cn)/
    (1+cn))^2))]|;
A44: q4`1= |.q.|* ((q`1/|.q.|-cn)/(1+cn)) by EUCLID:52;
A45: 1+cn>0 by A2,XREAL_1:148;
    0<=(q`2)^2 by XREAL_1:63;
    then (|.q.|)^2 =(q`1)^2+(q`2)^2 & 0+(q`1)^2<=(q`1)^2+(q`2)^2 by JGRAPH_3:1
,XREAL_1:7;
    then (q`1)^2/(|.q.|)^2 <= (|.q.|)^2/(|.q.|)^2 by XREAL_1:72;
    then (q`1)^2/(|.q.|)^2 <= 1 by A43,XCMPLX_1:60;
    then ((q`1)/|.q.|)^2 <= 1 by XCMPLX_1:76;
    then -1<=q`1/|.q.| by SQUARE_1:51;
    then -1-cn<=q`1/|.q.|-cn by XREAL_1:9;
    then (-(1+cn))/(1+cn)<=(( q`1/|.q.|-cn))/(1+cn) by A45,XREAL_1:72;
    then -1<=(( q`1/|.q.|-cn))/(1+cn) by A45,XCMPLX_1:197;
    then
A46: ( (q`1/|.q.|-cn) /(1+cn))^2<=1^2 by A45,A42,SQUARE_1:49;
    then
A47: 1-((q`1/|.q.|-cn)/(1+cn))^2>=0 by XREAL_1:48;
    1-(-((q`1/|.q.|-cn)/(1+cn)))^2>=0 by A46,XREAL_1:48;
    then 1-((-(q`1/|.q.|-cn))/(1+cn))^2>=0 by XCMPLX_1:187;
    then sqrt(1-((-(q`1/|.q.|-cn))/(1+cn))^2)>=0 by SQUARE_1:def 2;
    then sqrt(1-(-(q`1/|.q.|-cn))^2/(1+cn)^2)>=0 by XCMPLX_1:76;
    then sqrt(1-(q`1/|.q.|-cn)^2/(1+cn)^2)>=0;
    then
A48: sqrt(1-((q`1/|.q.|-cn)/(1+cn))^2)>=0 by XCMPLX_1:76;
A49: q4`2= |.q.|*( sqrt(1-((q`1/|.q.|-cn)/(1+cn))^2)) by EUCLID:52;
    then
A50: (q4`2)^2= (|.q.|)^2*( sqrt(1-((q`1/|.q.|-cn)/(1+cn))^2))^2
      .= (|.q.|)^2*(1-((q`1/|.q.|-cn)/(1+cn))^2) by A47,SQUARE_1:def 2;
    (|.q4.|)^2=(q4`1)^2+(q4`2)^2 by JGRAPH_3:1
      .=(|.q.|)^2 by A44,A50;
    then
A51: q4<>0.TOP-REAL 2 by A43,TOPRNS_1:23;
    cn-FanMorphN.q= |[ |.q.|* ((q`1/|.q.|-cn)/(1+cn)), |.q.|*( sqrt(1-((q
    `1/|.q.|-cn)/(1+cn))^2))]| by A2,A41,Th51;
    hence thesis by A2,A40,A49,A48,A51;
  end;
  dom ((cn-FanMorphN)|K111)=K111 by A33,RELAT_1:62
    .= the carrier of (TOP-REAL 2)|K111 by PRE_TOPC:8;
  then reconsider
  f4=(cn-FanMorphN)|K111 as Function of (TOP-REAL 2)|K111,(TOP-REAL
  2)|K1 by A16,A37,FUNCT_2:2;
  the carrier of (TOP-REAL 2)|K1=K1 by PRE_TOPC:8;
  then ((TOP-REAL 2)|K1)|K11=(TOP-REAL 2)|K111 & f2= f4 by A2,FUNCT_1:51
,GOBOARD9:2;
  then
A52: f2 is continuous by A2,A36,Th57,PRE_TOPC:26;
A53: the carrier of ((TOP-REAL 2)|K1)=K0 by PRE_TOPC:8;
  set T1= ((TOP-REAL 2)|K1)|K00,T2=((TOP-REAL 2)|K1)|K11;
A54: [#](((TOP-REAL 2)|K1)|K11)=K11 by PRE_TOPC:def 5;
  defpred P[Point of TOP-REAL 2] means $1`1<=cn*(|.$1.|) & $1`2>=0;
  {p: P[p]} is Subset of TOP-REAL 2 from DOMAIN_1:sch 7;
  then reconsider
  K004={p: p`1<=(cn)*(|.p.|) & p`2>=0} as Subset of (TOP-REAL 2);
A55: K004 /\ K1 c= K11
  proof
    let x be object;
    assume
A56: x in K004 /\ K1;
    then x in K004 by XBOOLE_0:def 4;
    then consider q1 being Point of TOP-REAL 2 such that
A57: q1=x and
A58: q1`1<=(cn)*(|.q1.|) and
    q1`2>=0;
    x in K1 by A56,XBOOLE_0:def 4;
    then
A59: ex q2 being Point of TOP-REAL 2 st q2=x & q2`2>=0 & q2 <>0.TOP-REAL 2
    by A2;
    q1`1/|.q1.|<=(cn)*(|.q1.|)/|.q1.| by A58,XREAL_1:72;
    then q1`1/|.q1.|<=(cn) by A57,A59,TOPRNS_1:24,XCMPLX_1:89;
    hence thesis by A57,A59;
  end;
A60: K004 is closed by Th59;
  the carrier of (TOP-REAL 2)|K1=K1 by PRE_TOPC:8;
  then ((TOP-REAL 2)|K1)|K00=(TOP-REAL 2)|K001 & f1= f3 by A2,FUNCT_1:51
,GOBOARD9:2;
  then
A61: f1 is continuous by A2,A36,Th56,PRE_TOPC:26;
A62: [#]((TOP-REAL 2)|K1)=K1 by PRE_TOPC:def 5;
  K11 c= K004 /\ K1
  proof
    let x be object;
    assume x in K11;
    then consider p such that
A63: p=x and
A64: p`1/|.p.|<=cn and
A65: p`2>=0 and
A66: p<>0.TOP-REAL 2;
    p`1/|.p.|*|.p.|<=(cn)*(|.p.|) by A64,XREAL_1:64;
    then p`1<=(cn)*(|.p.|) by A66,TOPRNS_1:24,XCMPLX_1:87;
    then
A67: x in K004 by A63,A65;
    x in K1 by A2,A63,A65,A66;
    hence thesis by A67,XBOOLE_0:def 4;
  end;
  then K11=K004 /\ [#]((TOP-REAL 2)|K1) by A62,A55,XBOOLE_0:def 10;
  then
A68: K11 is closed by A60,PRE_TOPC:13;
A69: K003 /\ K1 c= K00
  proof
    let x be object;
    assume
A70: x in K003 /\ K1;
    then x in K003 by XBOOLE_0:def 4;
    then consider q1 being Point of TOP-REAL 2 such that
A71: q1=x and
A72: q1`1>=(cn)*(|.q1.|) and
    q1`2>=0;
    x in K1 by A70,XBOOLE_0:def 4;
    then
A73: ex q2 being Point of TOP-REAL 2 st q2=x & q2`2>=0 & q2 <>0.TOP-REAL 2
    by A2;
    q1`1/|.q1.|>=(cn)*(|.q1.|)/|.q1.| by A72,XREAL_1:72;
    then q1`1/|.q1.|>=(cn) by A71,A73,TOPRNS_1:24,XCMPLX_1:89;
    hence thesis by A71,A73;
  end;
  K00 c= K003 /\ K1
  proof
    let x be object;
    assume x in K00;
    then consider p such that
A74: p=x and
A75: p`1/|.p.|>=cn and
A76: p`2>=0 and
A77: p<>0.TOP-REAL 2;
    p`1/|.p.|*|.p.|>=(cn)*(|.p.|) by A75,XREAL_1:64;
    then p`1>=(cn)*(|.p.|) by A77,TOPRNS_1:24,XCMPLX_1:87;
    then
A78: x in K003 by A74,A76;
    x in K1 by A2,A74,A76,A77;
    hence thesis by A78,XBOOLE_0:def 4;
  end;
  then K00=K003 /\ [#]((TOP-REAL 2)|K1) by A62,A69,XBOOLE_0:def 10;
  then
A79: K00 is closed by A34,PRE_TOPC:13;
A80: [#](((TOP-REAL 2)|K1)|K00)=K00 by PRE_TOPC:def 5;
A81: for p being object st p in ([#]T1)/\([#]T2) holds f1.p = f2.p
  proof
    let p be object;
    assume
A82: p in ([#]T1)/\([#]T2);
    then p in K00 by A80,XBOOLE_0:def 4;
    hence f1.p=f.p by FUNCT_1:49
      .=f2.p by A54,A82,FUNCT_1:49;
  end;
A83: K1 c= K00 \/ K11
  proof
    let x be object;
    assume x in K1;
    then consider p such that
A84: p=x & p`2>=0 & p<>0.TOP-REAL 2 by A2;
    per cases;
    suppose
      p`1/|.p.|>=cn;
      then x in K00 by A84;
      hence thesis by XBOOLE_0:def 3;
    end;
    suppose
      p`1/|.p.|<cn;
      then x in K11 by A84;
      hence thesis by XBOOLE_0:def 3;
    end;
  end;
  then [#](((TOP-REAL 2)|K1)|K00) \/ [#](((TOP-REAL 2)|K1)|K11) =[#]((
  TOP-REAL 2)|K1) by A80,A54,A62,XBOOLE_0:def 10;
  then consider h being Function of (TOP-REAL 2)|K1,(TOP-REAL 2)|D such that
A85: h=f1+*f2 and
A86: h is continuous by A80,A54,A79,A68,A61,A52,A81,JGRAPH_2:1;
A87: dom h=the carrier of ((TOP-REAL 2)|K1) by FUNCT_2:def 1;
A88: dom f1=the carrier of ((TOP-REAL 2)|K1)|K00 by FUNCT_2:def 1
    .=K00 by PRE_TOPC:8;
A89: for y being object st y in dom h holds h.y=f.y
  proof
    let y be object;
    assume
A90: y in dom h;
    per cases by A83,A87,A53,A90,XBOOLE_0:def 3;
    suppose
A91:  y in K00 & not y in K11;
      then y in dom f1 \/ dom f2 by A88,XBOOLE_0:def 3;
      hence h.y=f1.y by A15,A85,A91,FUNCT_4:def 1
        .=f.y by A91,FUNCT_1:49;
    end;
    suppose
A92:  y in K11;
      then y in dom f1 \/ dom f2 by A15,XBOOLE_0:def 3;
      hence h.y=f2.y by A15,A85,A92,FUNCT_4:def 1
        .=f.y by A92,FUNCT_1:49;
    end;
  end;
  K0=the carrier of ((TOP-REAL 2)|K0) by PRE_TOPC:8
    .=dom f by A7,FUNCT_2:def 1;
  hence thesis by A86,A87,A89,FUNCT_1:2,PRE_TOPC:8;
end;
