
theorem Th60:
  for a,b,c,d being Real, h being Function of TOP-REAL 2,
TOP-REAL 2,f being Function of I[01],TOP-REAL 2, O,I being Point of I[01] st c
<d & h=AffineMap(2/(b-a),-(b+a)/(b-a),2/(d-c),-(d+c)/(d-c)) & c <=(f.O)`2 & (f.
O)`2<=d & c <=(f.I)`2 & (f.I)`2<=d holds -1 <=((h*f).O)`2 & ((h*f).O)`2<=1 & -1
  <=((h*f).I)`2 & ((h*f).I)`2<=1
proof
  let a,b,c,d be Real, h be Function of TOP-REAL 2,TOP-REAL 2,f be
  Function of I[01],TOP-REAL 2, O,I be Point of I[01];
  set A=2/(b-a), B=-(b+a)/(b-a), C = 2/(d-c), D=-(d+c)/(d-c);
  assume that
A1: c <d and
A2: h=AffineMap(A,B,C,D) and
A3: c <=(f.O)`2 and
A4: (f.O)`2<=d and
A5: c <=(f.I)`2 and
A6: (f.I)`2<=d;
A7: (h.(f.O))= |[A*((f.O)`1)+B,C*((f.O)`2)+D]| by A2,JGRAPH_2:def 2;
A8: d-c >0 by A1,XREAL_1:50;
  then
A9: C >0 by XREAL_1:139;
  then C*d >= C*((f.O)`2) by A4,XREAL_1:64;
  then
A10: C*d+D >= C*((f.O)`2)+D by XREAL_1:6;
  (-1-D)/C =(-1+(d+c)/(d-c))/(2/(d-c))
    .=((-1)*(d-c)+(d+c))/(d-c)/(2/(d-c)) by A8,XCMPLX_1:113
    .= (d-c)*((c+c)/(d-c)/2) by XCMPLX_1:82
    .= ((d-c)*((c+c)/(d-c)))/2
    .=(c+c)/2 by A8,XCMPLX_1:87
    .= c;
  then C*((-1-D)/C) <= C*((f.O)`2) by A3,A9,XREAL_1:64;
  then -1-D <= C*((f.O)`2) by A9,XCMPLX_1:87;
  then
A11: -1-D+D <= C*((f.O)`2)+D by XREAL_1:6;
  C*c <=C*((f.I)`2) by A5,A9,XREAL_1:64;
  then
A12: C*c+D <= C*((f.I)`2)+D by XREAL_1:7;
A13: (h.(f.I))= |[A*((f.I)`1)+B,C*((f.I)`2)+D]| by A2,JGRAPH_2:def 2;
A14: dom f=the carrier of I[01] by FUNCT_2:def 1;
  then
A15: ((h*f).I)=(h.(f.I)) by FUNCT_1:13;
  C*d >= C*((f.I)`2) by A6,A9,XREAL_1:64;
  then
A16: C*d+D >= C*((f.I)`2)+D by XREAL_1:6;
A17: C*d+D = (2*d)/(d-c)+ -(d+c)/(d-c) by XCMPLX_1:74
    .= (2*d)/(d-c)+ (-(d+c))/(d-c) by XCMPLX_1:187
    .=(d+d+-(d+c))/(d-c) by XCMPLX_1:62
    .= 1 by A8,XCMPLX_1:60;
A18: C*c+D = (2*c)/(d-c)+ -(d+c)/(d-c) by XCMPLX_1:74
    .= (2*c)/(d-c)+ (-(d+c))/(d-c) by XCMPLX_1:187
    .=(c+c+-(d+c))/(d-c) by XCMPLX_1:62
    .=(-(d-c))/(d-c)
    .= -1 by A8,XCMPLX_1:197;
  ((h*f).O)=(h.(f.O)) by A14,FUNCT_1:13;
  hence thesis by A15,A7,A13,A18,A17,A11,A10,A16,A12,EUCLID:52;
end;
