reserve a, b, c, d, r, s for Real,
  n for Element of NAT,
  p, p1, p2 for Point of TOP-REAL 2,
  x, y for Point of TOP-REAL n,
  C for Simple_closed_curve,
  A, B, P for Subset of TOP-REAL 2,
  U, V for Subset of (TOP-REAL 2)|C`,
  D for compact with_the_max_arc Subset of TOP-REAL 2;

theorem Th60:
  diffX1_X2_1 is continuous Function of [:TOP-REAL 2, TOP-REAL 2:], R^1
proof
  reconsider Dx = diffX1_X2_1 as Function of [:T2,T2:],R^1 by TOPMETR:17;
  for p being Point of [:T2,T2:], V being Subset of R^1
  st Dx.p in V & V is open holds
  ex W being Subset of [:T2,T2:] st p in W & W is open & Dx.:W c= V
  proof
    let p be Point of [:T2,T2:], V be Subset of R^1 such that
A1: Dx.p in V and
A2: V is open;
A3: p = [p`1,p`2] by Lm5,MCART_1:21;
A4: diffX1_X2_1.p = p`1`1 - p`2`1 by Def3;
    set r = p`1`1 - p`2`1;
    reconsider V1 = V as open Subset of REAL by A2,BORSUK_5:39,TOPMETR:17;
    consider g being Real such that
A5: 0 < g and
A6: ].r-g,r+g.[ c= V1 by A1,A4,RCOMP_1:19;
    reconsider g as Element of REAL by XREAL_0:def 1;
    set W1 = {|[x,y]| where x, y is Real:
    p`1`1-g/2 < x & x < p`1`1+g/2};
    set W2 = {|[x,y]| where x, y is Real:
    p`2`1-g/2 < x & x < p`2`1+g/2};
    W1 c= the carrier of T2
    proof
      let a be object;
      assume a in W1;
      then ex x, y being Real st
      a = |[x,y]| & p`1`1-g/2 < x & x < p`1`1+g/2;
      hence thesis;
    end;
    then reconsider W1 as Subset of T2;
    W2 c= the carrier of T2
    proof
      let a be object;
      assume a in W2;
      then ex x, y being Real st
      a = |[x,y]| & p`2`1-g/2 < x & x < p`2`1+g/2;
      hence thesis;
    end;
    then reconsider W2 as Subset of T2;
    take [:W1,W2:];
A7: p`1 = |[p`1`1,p`1`2]| by EUCLID:53;
A8: 0/2 < g/2 by A5,XREAL_1:74;
    then
A9: p`1`1-g/2 < p`1`1-0 by XREAL_1:15;
    p`1`1+0 < p`1`1+g/2 by A8,XREAL_1:6;
    then
A10: p`1 in W1 by A7,A9;
A11: p`2 = |[p`2`1,p`2`2]| by EUCLID:53;
A12: p`2`1-g/2 < p`2`1-0 by A8,XREAL_1:15;
    p`2`1+0 < p`2`1+g/2 by A8,XREAL_1:6;
    then p`2 in W2 by A11,A12;
    hence p in [:W1,W2:] by A3,A10,ZFMISC_1:def 2;
A13: W1 is open by PSCOMP_1:19;
    W2 is open by PSCOMP_1:19;
    hence [:W1,W2:] is open by A13,BORSUK_1:6;
    let b be object;
    assume b in Dx.:[:W1,W2:];
    then consider a being Point of [:T2,T2:] such that
A14: a in [:W1,W2:] and
A15: Dx.a = b by FUNCT_2:65;
A16: a = [a`1,a`2] by Lm5,MCART_1:21;
A17: diffX1_X2_1.a = a`1`1 - a`2`1 by Def3;
    a`1 in W1 by A14,A16,ZFMISC_1:87;
    then consider x1, y1 being Real such that
A18: a`1 = |[x1,y1]| and
A19: p`1`1-g/2 < x1 and
A20: x1 < p`1`1+g/2;
A21: a`1`1 = x1 by A18,EUCLID:52;
A22: p`1`1-g/2+g/2 < x1+g/2 by A19,XREAL_1:6;
A23: p`1`1-x1 > p`1`1-(p`1`1+g/2) by A20,XREAL_1:15;
A24: p`1`1-x1 < x1+g/2-x1 by A22,XREAL_1:9;
    p`1`1-x1 > -g/2 by A23;
    then
A25: |.p`1`1-x1.| < g/2 by A24,SEQ_2:1;
    a`2 in W2 by A14,A16,ZFMISC_1:87;
    then consider x2, y2 being Real such that
A26: a`2 = |[x2,y2]| and
A27: p`2`1-g/2 < x2 and
A28: x2 < p`2`1+g/2;
A29: a`2`1 = x2 by A26,EUCLID:52;
A30: p`2`1-g/2+g/2 < x2+g/2 by A27,XREAL_1:6;
A31: p`2`1-x2 > p`2`1-(p`2`1+g/2) by A28,XREAL_1:15;
A32: p`2`1-x2 < x2+g/2-x2 by A30,XREAL_1:9;
    p`2`1-x2 > -g/2 by A31;
    then |.p`2`1-x2.| < g/2 by A32,SEQ_2:1;
    then
A33: |.p`1`1-x1.|+|.p`2`1-x2.| < g/2+g/2 by A25,XREAL_1:8;
    |.p`1`1-x1-(p`2`1-x2).| <= |.p`1`1-x1.|+|.p`2`1-x2.| by COMPLEX1:57;
    then |.-(p`1`1-x1-(p`2`1-x2)).| <= |.p`1`1-x1.|+|.p`2`1-x2.|
    by COMPLEX1:52;
    then |.x1-x2-r.| < g by A33,XXREAL_0:2;
    then a`1`1 - a`2`1 in ].r-g,r+g.[ by A21,A29,RCOMP_1:1;
    hence thesis by A6,A15,A17;
  end;
  hence thesis by JGRAPH_2:10;
end;
