reserve A,B,p,q,r,s for Element of LTLB_WFF,
  i,j,k,n for Element of NAT,
  X for Subset of LTLB_WFF,
  f,f1 for FinSequence of LTLB_WFF,
  g for Function of LTLB_WFF,BOOLEAN;

theorem {}LTLB_WFF |- (con nex f)/.(len con nex f)=>('X' (con f)/.(len con f))
   proof
     set t = TVERUM;
     per cases;
     suppose
A1:    len f = 0;
       then len nex f = 0 by Def5;
       then A2: nex f = {};
       t is ctaut by Th4;
       then t in LTL_axioms by LTLAXIO1:def 17;
       then A3: {}l |- t by LTLAXIO1:42;
       then A4: {}l |- 'X' t by LTLAXIO1:44;
       t => (('X' t) => (t => 'X' t)) is ctaut by Th34;
       then
       t => (('X' t) => (t => 'X' t)) in LTL_axioms by LTLAXIO1:def 17;
       then {}l |- t => (('X' t) => (t => 'X' t)) by LTLAXIO1:42;
       then A5: {}l |- (('X' t) => (t => 'X' t)) by LTLAXIO1:43,A3;
       f = {} by A1;
       hence thesis by A5,LTLAXIO1:43,A4, Th10, A2;
     end;
     suppose
A6:    0 < len f;
       defpred P[Nat] means $1 <= len f implies
       {}l |- (con nex f)/.$1 => 'X' (con f)/.$1;
A7:    now
         let k being non zero Nat;
         set p = (con nex f)/.k, q = (con nex f)/.(k+1), r = (nex f)/.(k+1),
         s = (con f)/.(k+1), t = (con f)/.k;
         assume
A8:      P[k];
         thus P[k + 1]
         proof
           (q => (p '&&' r)) => ((p => 'X' t) => (q => (('X' t) '&&' r)))
           is ctaut by Th44;then
           (q => (p '&&' r)) => ((p => 'X' t) => (q => (('X' t) '&&' r)))
           in LTL_axioms by LTLAXIO1:def 17;then
A9:        {}l |- (q => (p '&&' r)) =>
           ((p => 'X' t) => (q => (('X' t) '&&' r))) by LTLAXIO1:42;
           reconsider k1 = k as Element of NAT by ORDINAL1:def 12;
A10:       1 <= k1 by NAT_1:25;
           assume
A11:       k+1 <= len f;
           then A12: k1 + 1 <= len con f by Def2;
A13:       k1 + 1 <= len nex f by A11,Def5;
           then r = (nex f).(k1+1) by NAT_1:12,FINSEQ_4:15
           .= 'X' f/.(k+1) by Def5, NAT_1:12,A11;then
A14:       {}l |- (('X' t) '&&' r) => ('X' (t '&&' f/.(k+1))) by LTLAXIO1:53;
A15:       k < len f by A11,NAT_1:13;
           then A16: k1 < len nex f by Def5;
           k1 + 1 <= len con nex f by A13,Def2;
           then q = (con nex f).(k1+1) by NAT_1:12,FINSEQ_4:15
           .= p '&&' r by Def2,A16,A10;
           then q => (p '&&' r) is ctaut by Th24;
           then q => (p '&&' r) in LTL_axioms by LTLAXIO1:def 17;
           then {}l |- q => (p '&&' r) by LTLAXIO1:42;then
           {}l |- ((p => 'X' t) => (q => (('X' t) '&&' r))) by A9, LTLAXIO1:43;
           then A17: {}l |- q => (('X' t) '&&' r)
           by LTLAXIO1:43, A11,NAT_1:13,A8;
           t '&&' f/.(k+1) = (con f).(k1+1) by Def2,A10, A15
           .= s by NAT_1:12,A12,FINSEQ_4:15;
           hence {}l |- q => 'X' s by A14,A17,LTLAXIO1:47;
         end;
       end;
A18:   0 < len nex f by A6,Def5;
A19:   P[1]
       proof
         assume
A20:     1 <= len f;
         then 1 <= len nex f by Def5;
         then 1 <= len con nex f by Def2;
         then A21: (con nex f)/.1 = (con nex f).1 by FINSEQ_4:15
         .= (nex f).1 by Def2,A18
         .= 'X' f/.1 by Def5,A20;
         ('X' f/.1) => ('X' f/.1) is ctaut by Th24;
         then A22: ('X' f/.1) => ('X' f/.1) in LTL_axioms by LTLAXIO1:def 17;
         'X'(con f)/.1 = 'X' f/.1 by Th6,A20;
         hence thesis by A22,LTLAXIO1:42,A21;
       end;
       for k be non zero Nat holds P[k] from NAT_1:sch 10(A19,A7);
       then A23: {}l |- (con nex f)/.(len f) => 'X' (con f)/.(len f) by A6;
A24:   len nex f > 0 by A6,Def5;
       len f = len nex f by Def5
       .= len con nex f by Def2,A24;
       hence thesis by Def2,A6,A23;
     end;
   end;
