reserve p,q,r,s,A,B for Element of PL-WFF,
  F,G,H for Subset of PL-WFF,
  k,n for Element of NAT,
  f,f1,f2 for FinSequence of PL-WFF;
reserve M for PLModel;

theorem naab:
  F |- ('not' A) => (A => B)
 proof
   set f = F \/ {'not' A} \/ {A};
   A in f by ZFMISC_1:31,XBOOLE_1:11;then
A1: f |- A by th42;
    f = F \/  {A} \/ {'not' A} by XBOOLE_1:4;then
    'not' A in f by ZFMISC_1:31,XBOOLE_1:11;then
A2: f |- 'not' A by th42;
    A => ('not' B => A) in PL_axioms by withplax;then
    f |- A => ('not' B => A) by th42;then
A4: f |- ('not' B => A) by th43,A1;
    'not' A => ('not' B => 'not' A) in PL_axioms by withplax;then
    f |- 'not' A => ('not' B => 'not' A) by th42;then
A3: f |- 'not' B => 'not' A by th43,A2;
    ('not' B => 'not' A) => (('not' B => A)=>B) in PL_axioms by withplax;
    then f |- ('not' B => 'not' A) => (('not' B => A)=>B) by th42;then
    f |- ('not' B => A)=>B by th43,A3;then
    f |- B by th43,A4;then
    F \/ {'not' A} |- A => B by ded;
    hence thesis by ded;
  end;
