reserve i,j,k,l,m,n for Nat,
  D for non empty set,
  f for FinSequence of D;
reserve X for compact Subset of TOP-REAL 2;
reserve r for Real;
reserve f for non trivial FinSequence of TOP-REAL 2;
reserve f for non constant standard special_circular_sequence;

theorem Th60:
  for f being FinSequence of TOP-REAL 2, p being Point of TOP-REAL
2 st f is being_S-Seq & p <> f/.1 & (p`1 = (f/.1)`1 or p`2 = (f/.1)`2) & LSeg(p
  ,f/.1) /\ L~f = {f/.1} holds <*p*>^f is S-Sequence_in_R2
proof
  let f be FinSequence of TOP-REAL 2, p be Point of TOP-REAL 2 such that
A1: f is being_S-Seq and
A2: p <> f/.1 and
A3: p`1 = (f/.1)`1 or p`2 = (f/.1)`2 and
A4: LSeg(p,f/.1) /\ L~f = {f/.1};
  reconsider f as S-Sequence_in_R2 by A1;
A5: len f >= 1+1 by TOPREAL1:def 8;
  then
A6: f/.1 in LSeg(f,1) by TOPREAL1:21;
  set g = <*p*>^f;
  len g = len<*p*> + len f by FINSEQ_1:22;
  then len g >= len f by NAT_1:11;
  then
A7: len g >= 2 by A5,XXREAL_0:2;
  now
    assume
A8: p in rng f;
    rng f c= L~f & p in LSeg(p,f/.1) by A5,RLTOPSP1:68,SPPOL_2:18;
    then p in {f/.1} by A4,A8,XBOOLE_0:def 4;
    hence contradiction by A2,TARSKI:def 1;
  end;
  then {p} misses rng f by ZFMISC_1:50;
  then <*p*> is one-to-one & rng<*p*> misses rng f by FINSEQ_1:39,FINSEQ_3:93;
  then
A9: g is one-to-one by FINSEQ_3:91;
  L~<*p*> = {} by SPPOL_2:12;
  then L~<*p*> /\ L~f = {};
  then
A10: L~<*p*> misses L~f;
A11: 1 in dom f by FINSEQ_5:6;
A12: now
    let i such that
A13: 1+1<=i and
A14: i+1 <= len f;
A15: 2 in dom f by A5,FINSEQ_3:25;
    now
      assume f/.1 in LSeg(f,i);
      then
A16:  f/.1 in LSeg(f,1) /\ LSeg(f,i) by A6,XBOOLE_0:def 4;
      then
A17:  LSeg(f,1) meets LSeg(f,i);
      now
        per cases by A13,XXREAL_0:1;
        case
A18:      i = 1+1;
          then LSeg(f,1) /\ LSeg(f,1+1) = {f/.2} by A14,TOPREAL1:def 6;
          hence f/.1 = f/.2 by A16,A18,TARSKI:def 1;
        end;
        case
          i > 1+1;
          hence contradiction by A17,TOPREAL1:def 7;
        end;
      end;
      then f.1 = f/.2 by A11,PARTFUN1:def 6
        .= f.2 by A15,PARTFUN1:def 6;
      hence contradiction by A11,A15,FUNCT_1:def 4;
    end;
    then not f/.1 in LSeg(f,i) /\ LSeg(p,f/.1) by XBOOLE_0:def 4;
    then
A19: LSeg(f,i) /\ LSeg(p,f/.1) <> {f/.1} by TARSKI:def 1;
    LSeg(f,i) /\ LSeg(p,f/.1) c= {f/.1} by A4,TOPREAL3:19,XBOOLE_1:26;
    then LSeg(f,i) /\ LSeg(p,f/.1) = {} by A19,ZFMISC_1:33;
    hence LSeg(f,i) misses LSeg(p,f/.1);
  end;
A20: len<*p*> = 1 by FINSEQ_1:39;
  then
A21: <*p*> is s.n.c. & <*p*>/.len <*p*> = p by FINSEQ_4:16,SPPOL_2:33;
A22: now
    let i such that
    1<=i;
A23: 2 <= i+2 by NAT_1:11;
    assume i+2 <= len <*p*>;
    hence LSeg(<*p*>,i) misses LSeg(p,f/.1) by A20,A23,XXREAL_0:2;
  end;
  LSeg(p,f/.1) /\ LSeg(f,1) = {f/.1} by A4,A6,TOPREAL3:19,ZFMISC_1:124;
  then g is unfolded s.n.c. special by A3,A21,A10,A22,A12,GOBOARD2:8,SPPOL_2:29
,36;
  hence thesis by A9,A7,TOPREAL1:def 8;
end;
