
theorem lift3c:
for F being Field,
    A being AlgebraicClosure of F,
    L being A-monomorphic A-homomorphic Field
for g being Monomorphism of A,L holds (Image g) is algebraic-closed
proof
let F be Field, E be AlgebraicClosure of F;
let L be E-monomorphic E-homomorphic Field, g be Monomorphism of E,L;
H: rng g = the carrier of (Image g) by RING_2:def 6; then
reconsider f = g" as Function of (Image g),E;
A: f is additive multiplicative unity-preserving monomorphism
   proof
   B1: now let a,b be Element of Image g;
     consider x being object such that
     A1: x in dom g & g.x = a by H,FUNCT_1:def 3;
     reconsider x as Element of E by A1;
     consider y being object such that
     A2: y in dom g & g.y = b by H,FUNCT_1:def 3;
     reconsider y as Element of E by A2;
     A3: dom g = the carrier of E by FUNCT_2:def 1;
     A4: g".b = y by A2,FUNCT_1:34;
     A5: [a,b] in [:the carrier of Image g,the carrier of Image g:]
              by ZFMISC_1:def 2;
     g.(x + y) = g.x + g.y by VECTSP_1:def 20
              .= ((the addF of L)||(the carrier of Image g)).(a,b)
                 by A1,A2,A5,FUNCT_1:49
              .= a + b by EC_PF_1:def 1;
     hence f.(a+b) = x + y by A3,FUNCT_1:34
                  .= f.a + f.b by A1,A4,FUNCT_1:34;
     end;
   B2: now let a,b be Element of Image g;
     consider x being object such that
     A1: x in dom g & g.x = a by H,FUNCT_1:def 3;
     reconsider x as Element of E by A1;
     consider y being object such that
     A2: y in dom g & g.y = b by H,FUNCT_1:def 3;
     reconsider y as Element of E by A2;
     A3: dom g = the carrier of E by FUNCT_2:def 1;
     A4: g".b = y by A2,FUNCT_1:34;
     A5: [a,b] in [:the carrier of Image g,the carrier of Image g:]
              by ZFMISC_1:def 2;
     g.(x * y) = g.x * g.y by GROUP_6:def 6
              .= ((the multF of L)||(the carrier of Image g)).(a,b)
                 by A1,A2,A5,FUNCT_1:49
              .= a * b by EC_PF_1:def 1;
     hence f.(a*b) = x * y by A3,FUNCT_1:34
                  .= f.a * f.b by A1,A4,FUNCT_1:34;
     end;
  B3: dom g = the carrier of E by FUNCT_2:def 1;
  g.(1_E) = 1_L by GROUP_1:def 13 .= 1_(Image g) by EC_PF_1:def 1;
  then f is additive multiplicative unity-preserving by B1,B2,B3,FUNCT_1:34;
  hence thesis;
  end; then
reconsider E1 = E as (Image g)-monomorphic (Image g)-homomorphic Field
   by RING_2:def 4,RING_3:def 3;
reconsider f as Monomorphism of (Image g),E1 by A;

now let p be non constant Polynomial of (Image g);
  reconsider p1 = p as
     Element of the carrier of Polynom-Ring (Image g) by POLYNOM3:def 10;
  C: deg p > 0 by RATFUNC1:def 2; then
  reconsider p1 as non constant
     Element of the carrier of Polynom-Ring (Image g) by RING_4:def 4;
  reconsider q = (PolyHom f).p1 as Polynomial of E;
  deg p1 = deg (PolyHom f).p1 by FIELD_1:31; then
  reconsider q = (PolyHom f).p1 as non constant Polynomial of E
       by C,RATFUNC1:def 2;
  consider a being Element of E such that
  B: a is_a_root_of q by POLYNOM5:def 8;
  reconsider r = q as Element of the carrier of Polynom-Ring E;
  F: dom(PolyHom f) = the carrier of Polynom-Ring(Image g) by FUNCT_2:def 1;
  E: (PolyHom g).((PolyHom f).p1) = p1
     proof
     dom g = the carrier of E1 by FUNCT_2:def 1; then
     reconsider g1 = g as Function of E1,(Image g) by H,FUNCT_2:1;
     Z: g1 is additive multiplicative unity-preserving
        proof
        now let a,b be Element of E1;
          reconsider a1 = a, b1 = b as Element of E;
          Z1: [g1.a,g1.b] in
              [:the carrier of Image g,the carrier of Image g:]
              by ZFMISC_1:def 2;
          thus g1.(a+b)
             = g.a1 + g.b1 by VECTSP_1:def 20
            .= ((the addF of L)||(the carrier of Image g)).(g1.a,g1.b)
               by Z1,FUNCT_1:49
            .= g1.a + g1.b by EC_PF_1:def 1;
          end;
        hence g1 is additive;
        now let a,b be Element of E1;
          reconsider a1 = a, b1 = b as Element of E;
          Z1: [g1.a,g1.b] in
              [:the carrier of Image g,the carrier of Image g:]
              by ZFMISC_1:def 2;
          thus g1.(a*b)
             = g.a1 * g.b1 by GROUP_6:def 6
            .= ((the multF of L)||(the carrier of Image g)).(g1.a,g1.b)
               by Z1,FUNCT_1:49
            .= g1.a * g1.b by EC_PF_1:def 1;
          end;
        hence g1 is multiplicative;
        g1.(1_E1) = 1_L by GROUP_1:def 13
                 .= 1_(Image g) by EC_PF_1:def 1;
        hence thesis;
        end;
     reconsider Ig = (Image g) as E1-homomorphic Field by Z,RING_2:def 4;
     reconsider g1 as additive Function of E1,Ig by Z;
     G: g1 * f = id(Image g)
        proof
        now let o be object;
          assume o in dom(g1 * f); then
          reconsider a = o as Element of Image g;
          (g1*f).a = a by H,FUNCT_1:35;
          hence (g1*f).o = id(Image g).o;
          end;
        hence thesis by FUNCT_2:def 1;
        end;
     H: PolyHom g1 = PolyHom g
        proof
        now let o be object;
          assume o in the carrier of Polynom-Ring E1;
          then reconsider a = o as Element of the carrier of Polynom-Ring E1;
          reconsider b = a as Element of the carrier of Polynom-Ring E;
          now let i be Nat;
             thus ((PolyHom g).b).i = g.(b.i) by FIELD_1:def 2
                              .= ((PolyHom g1).a).i by FIELD_1:def 2;
             end;
          then (PolyHom g1).a = (PolyHom g).b;
          hence (PolyHom g1).o = (PolyHom g).o;
          end;
        hence thesis;
        end;
     thus (PolyHom g).((PolyHom f).p1)
        = ((PolyHom g1) * (PolyHom f)).p1 by F,H,FUNCT_1:13
       .= (id(Polynom-Ring (Image g))).p1 by G,ll2
       .= p1;
     end;
  dom g = the carrier of E by FUNCT_2:def 1; then
  reconsider ga = g.a as Element of (Image g) by H,FUNCT_1:3;
  L is FieldExtension of (Image g) by FIELD_4:7; then
  eval(p,ga) = eval((PolyHom g).r,g.a) by E,FIELD_4:27
            .= 0.L by B,FIELD_1:34,POLYNOM5:def 7
            .= 0.(Image g) by RING_2:def 6;
  hence p is with_roots by POLYNOM5:def 8,POLYNOM5:def 7;
  end;
hence thesis by alg2;
end;
